Wednesday Workshop

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|465|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-

Whirlpool

by irondirgible for Workshop #018

This is what i came up with. It kinda stretches the water theme,though.

Cursors, Space and B, as shown on title screen.

Click to download this entry

Pokey

by irondirgible for Workshop #099

You must type the letters that appear next to the balloon to move in that direction, avoiding the needles (white lines) and getting the gold (yellow blocks).

Keyboard

Graphics 800,600,16,2
SetBuffer BackBuffer()
SeedRnd MilliSecs()

Global score
Global needle_time#
Global needle_rate# = 1000

Type needle
	Field x
	Field y
	Field dir
	Field speed
	Field class
End Type

Global mode = 0
Global start = True 
Global string_length = 2 ;XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX AMOUNT OF LETTERS
Dim last_strokes(string_length)

Global balloon_x = 400
Global balloon_y = 300
Global balloon_size = 100
Global balloon_dir = 0
Global balloon_speed = 1
Dim balloon_color(2)
Dim dir_letters(3,string_length)

Global needle_x
Global needle_y
Global needle_speed
Global needle_length
Global needle_dir

RANDOMIZE_LETTERS()
While Not KeyDown(1)
Text 0,0,"score:"+score
	RESET()
	GET_KEYSTROKES()
	CREATE_NEEDLES()
	MOVE_NEEDLES()
	CHANGE_BALLOON_DIR()
	MOVE_BALLOON()
	DRAW_ALL()
	WRITE_PROMPTS()
Flip
Cls
Wend 
Function CREATE_NEEDLES()
	Local dir 
	If MilliSecs() => needle_time Then 
		needle_time = MilliSecs() + needle_rate
		needle_rate = needle_rate*.98
		dir = Rand(0,3)
		n.needle = New needle
			Select dir 
				Case 0
					n\dir = 2
					n\x = Rand(50,750)
					n\y = 0
				Case 1
					n\dir = 3
					n\y = Rand(50,550)
					n\x = 0
				Case 2
					n\dir = 0
					n\x = Rand(50,750)
					n\y = 600
				Case 3
					n\dir = 1
					n\x = 800
					n\y = Rand(50,550)
			End Select
		dir = Rand(0,5)
		If dir = 5 Then n\class = 1
		n\speed = 2  ;XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX NEEDLE SPEED
	EndIf 
End Function 
Function MOVE_NEEDLES()
For n.needle = Each needle
	Select n\dir
 	Case 0
  		n\y = n\y - n\speed
 	Case 1
    	n\x = n\x - n\speed
  	Case 2
   		n\y = n\y + n\speed
  	Case 3
   		n\x = n\x + n\speed
 	End Select
	If n\x > 800 Or n\x < 0 Or n\y > 600 Or n\y < 0 Then Delete n : score = score + 100 
Next 
End Function 			
Function GET_KEYSTROKES()
	Local letter
	
	letter = GetKey()
	
	If letter => 97 And letter <= 122 Then 
		For i1 = 1 To string_length
			last_strokes((string_length-i1)+1) = last_strokes(string_length-i1)
		Next 
		last_strokes(0) = letter	
	EndIf 
End Function
Function RESET()
Local del
	For n.needle = Each needle
		del = False
		If Sqr((n\x-balloon_x)*(n\x-balloon_x)+(n\y-balloon_y)*(n\y-balloon_y)) <= balloon_size/2 Then
			If n\class = 1 Then 
				score = score + 1000
				del = True 
			EndIf 
			If n\class = 0 Then  
				Delete Each needle
				balloon_x = 400
				balloon_y = 300
				balloon_dir = 0
				score = 0
				start = True 
				Dim dir_letters(3,string_length)
				Dim last_strokes(string_length)
				RANDOMIZE_LETTERS()
				Cls 
				Text 400,300,"POP!"
				Flip
				Delay 300
			EndIf 
		EndIf 
		If del = True Then Delete n
	Next 
End Function 
Function RANDOMIZE_LETTERS()
	Local letter
	Local recur
	For i1 = 0 To 3
		For i2 = 0 To string_length
			letter = Rand(1,26)
			dir_letters(i1,i2) = 96+letter
		Next 
		For i3 = 0 To i1 - 1
			If i1 => 0 Then 
				For i2 = 0 To string_length
					If dir_letters(i3,i2) >< dir_letters(i1,i2) Then Exit
					If i2 = string_length Then recur = True
				Next 
			EndIf 
		Next 
		If recur = True Then i1 = i1 - 1
		recur = False
	Next 	

End Function 
Function CHANGE_BALLOON_DIR()
 For i1 = 0 To 3
  For i2 = 0 To string_length
   If dir_letters(i1,i2) >< last_strokes(string_length-i2) Then Exit
   If i2 = string_length Then balloon_dir = i1 : RANDOMIZE_LETTERS() : start = False 
  Next 
 Next
End Function
Function WRITE_PROMPTS()
 If mode = 0 ; text
  For i2 = 0 To string_length
   Text balloon_x-(string_length*11/2)+i2*11,balloon_y-(balloon_size-20),Chr$(dir_letters(0,i2))
   Text (balloon_x-balloon_size/2)-(string_length*11)+i2*11-11,balloon_y,Chr$(dir_letters(1,i2))
   Text balloon_x-(string_length*11/2)+i2*11,balloon_y+(balloon_size/2)+5,Chr$(dir_letters(2,i2))
   Text balloon_x+balloon_size/2+i2*11+11,balloon_y,Chr$(dir_letters(3,i2))
  Next
 EndIf

 If mode = 1 ; binary
  For i2 = 0 To string_length
   Text balloon_x-(string_length*33/2)+i2*33,balloon_y-(balloon_size-20),(dir_letters(0,i2))
   Text (balloon_x-balloon_size/2)-(string_length*33)+i2*33-33,balloon_y,(dir_letters(1,i2))
   Text balloon_x-(string_length*33/2)+i2*33,balloon_y+(balloon_size/2)+5,(dir_letters(2,i2))
   Text balloon_x+balloon_size/2+i2*33+33,balloon_y,(dir_letters(3,i2))
  Next
 EndIf
End Function
Function MOVE_BALLOON()
If start = False 
	Select balloon_dir
 	Case 0
  		balloon_y = balloon_y - balloon_speed
 	Case 1
    	balloon_x = balloon_x - balloon_speed
  	Case 2
   		balloon_y = balloon_y + balloon_speed
  	Case 3
   		balloon_x = balloon_x + balloon_speed
 	End Select
	If balloon_x > 800 Then balloon_dir = 1 
	If balloon_x < 0 Then balloon_dir = 3
	If balloon_y > 600 Then balloon_dir = 0
	If balloon_y < 0 Then balloon_dir = 2
EndIf 
End Function
Function DRAW_ALL()
	Color 255,0,0
		Oval balloon_x-balloon_size/2,balloon_y-balloon_size/2,balloon_size,balloon_size
		Rect balloon_x-10,balloon_y+balloon_size/2-5,20,10
	Color 255,255,255
	For n.needle = Each needle
		If n\class = 1 Then 
			Color 255,255,0
			Rect n\x-10,n\y-10,20,20
			Color 255,255,255
		EndIf 
		If n\class = 0 Then 
		Select n\dir
			Case 0
				Line n\x,n\y,n\x,n\y+35
			Case 1	
				Line n\x,n\y,n\x+35,n\y	
			Case 2
				Line n\x,n\y,n\x,n\y-35
			Case 3
				Line n\x,n\y,n\x-35,n\y
			End Select 
		EndIf
	Next 
End Function

100x100

by irondirgible for Workshop #100

Juggle the blocks so that only same coloured blocks hit the rectangle at the bottom.

Mouse

Click to download this entry