Wednesday Workshop

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|466|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-
Water Balunacy!

by tnt23 for Workshop #049
Splash the water bombs on the Blue guys.
Mouse (Cursor + Enter during menus)
Graphics3D 640,480
SeedRnd MilliSecs()
SetBuffer BackBuffer()
AppTitle "Water Balunacy"

If b3d Then Gosub Initialize3D

;;constants
Const g# = 0.4 ;gravity in px/frame
Const numofdrops = 25 ; per splash
Const numofclouds = 5 ;total number of clouds
Const PLAY = 0
Const HELP = 1
Const QUIT = 2
Const menu = 0
Const ingame = 1
Const readhelp = 2
Const gameover = 3
Const b3d = True 

;;scancodes
Const up = 200
Const down = 208
Const enter = 28

;;global vars
Global level
Global score
Global lives
Global prelives
Global status 
Global s
Global dx#,dy#,gundx#,gundy#
Global angle#,ex#,ey#
Global start

;;images
Global gfxcloud = CreateImage(120,90)
Global gfxguy = CreateImage(50,80,2) : MaskImage gfxguy,255,0,255

;;fonts
Global comic = LoadFont("Comic Sans MS",48,1)
Global arial = LoadFont("Arial Black",60)
Global smarial = LoadFont("Arial Black",32)
Global vsmarial = LoadFont("Arial",16,1)

;;types
Type drop
	Field x#,y#,w,h
	Field dx#,dy#
End Type

Type balloon
	Field x#,y#
	Field dx#,dy#
End Type

Type cloud
	Field x#,y#,z
	Field dx#
End Type

Type enemy
	Field x#,y#
	Field dx#,dy#
	Field f
End Type

Initialize()
ResetEverything()
;;MAIN LOOP;;
While Not KeyDown(1)
	Cls
	Update3D()
	UpdateParts()
	Select status
	;{
	Case ingame
		UpdateBalloons()
		UpdateInput()
		UpdateLauncher()
		DrawHUD()
		UpdateAI()
	Case gameover 
		UpdateGameOver()
	Case menu
		UpdateMenu()
	Case readhelp
		PrintHelp()
	Default
		status = menu
	;}
	End Select
	
	Delay 10
	Flip
Wend:End
;;END MAIN LOOP;;

;;functions

Function CreateBalloon(x,y)
	b.balloon = New balloon
	
	b\x = x : b\y = y
	
	b\dx = gundx#*15
	b\dy = gundy#*15
End Function

Function UpdateBalloons()
	For b.balloon = Each balloon
		b\dy = b\dy + g
		b\y = b\y + b\dy
		b\x = b\x + b\dx
		
		Color 255,0,0
		Oval b\x,b\y,25,35,1
				
		If b\y > GraphicsHeight()-30 Or b\x < 0 Or b\x > GraphicsWidth()-20 Then 
			score = score-2
			CreateSplash(b\x+12.5,b\y+17.5,b\dy)
			Delete b
		EndIf 
	Next
End Function

Function CreateSplash(x,y,a)
	 For i = 0 To numofdrops
		d.drop = New drop
		d\x = x + Rand(-10,10)
		d\y = y + Rand(-10,10)
		
		d\dx = Rnd#(-3,3)
		d\dy = Rnd#(-1,-4)*(a/5)
		
		d\w = Rand(1,3) : d\h = d\w
	Next
End Function

Function UpdateParts() ;;update particles/types
	;;water drops
	For d.drop = Each drop
		d\dy = d\dy + g
		
		d\x = d\x + d\dx
		d\y = d\y + d\dy
		
		Color 0,55,255
		Oval d\x,d\y,d\w,d\h,1
		
		If d\y >= GraphicsHeight() Then Delete d
	Next
	
	;;clouds
	For c.cloud = Each cloud
		c\x = c\x + c\dx*c\z
	
		If c\x > 640 Then 
			c\x = -ImageWidth(gfxcloud)-Rand(10,50)
			c\dx = Rnd#(0.05,0.15)
		EndIf
						
		DrawImage gfxcloud, c\x,c\y
	Next
	
End Function

Function UpdateInput()
	If MouseHit(1) And MouseY()<440 Then CreateBalloon(ex#-5,ey#-5)
End Function

Function DrawCloudImage() ;;draws the cloud image
	SetBuffer ImageBuffer(gfxcloud)

	Color 200,200,200
	Oval 10,10,50,50,1

	Color 240,240,240
	Oval 45,10,40,40,1

	Color 225,225,225
	Oval 35,35,35,35,1

	Color 240,240,240
	Oval 70,10,50,50,1

	Color 210,210,210
	Oval 60,35,40,40,1
	
	Color 0,0,0
	
	For x = 0 To 120 Step 2
		For y = 0 To 90 Step 2
			Plot x,y
		Next
	Next
End Function 

Function CreateClouds() 
	;;create clouds; scatter them in sky
	For i = 0 To numofclouds-1
		c.cloud = New cloud
		
		c\y = Rand(10)
		c\dx = Rnd#(0.05,0.15)
		
		Select i+1
			Case 1
				c\z = 1
				c\x = Rand(0,200)
			Case 2
				c\z = 1
				c\x = Rand(150,280)
			Case 3
				c\z = 2
				c\x = Rand(300,500)
			Case 4
				c\z = 3
				c\x = Rand(550,600)
			Case 5
				c\z = 3
				c\x = Rand(600,630)
			Default
				RuntimeError("Could not draw clouds!")
		End Select	
	Next
End Function

Function DrawGuy()
	For f = 0 To 1
		SetBuffer ImageBuffer(gfxguy,f)
	
		Color 255,0,255
		Rect 0,0,ImageWidth(gfxguy),ImageHeight(gfxguy),1
	
		;;head
		If f Then Color 255,0,0 Else Color 0,0,255
		Oval 10,0,40,40,1
		Gray 0
		Oval 10,0,40,40,0

		;;torso
		Gray 255
		Rect 29,40,1,25,1

		;;arms
		Line 29,50,10,45
		Line 29,50,50,45

		;;legs
		Line 29,65,20,80
		Line 29,65,40,80

		;;eyes
		Gray 255
		Oval 15,5,12,12,1
		Oval 30,5,12,12,1
		
		Gray 0
		Oval 15,5,12,12,0
		Oval 30,5,12,12,0

		Oval 19,10,5,5,1
		Oval 34,10,5,5,1

		Gray 255
		Plot 20,11
		Plot 35,11

		;;mouth
		Gray 0
		Oval 19,20,20,10,0

		If f Then Color 255,0,0 Else Color 0,0,255
		Rect 19,20,20,5,1
	Next
End Function

Function Update3D()
	If b3d Then
		UpdateWorld()
		RenderWorld()
	Else
		Color 255,255,0
		Oval 560,-20,100,100,1
		
		Color 0,200,0
		Rect 0,400,640,80,1
	EndIf
End Function

Function Gray(c)
	Color c,c,c
End Function 

Function UpdateMenu()
	For i = 0 To 2
		Gray 0
		SetFont arial
		Text 320,100,"Water Balunacy!",1,1
		
		If s = i Then Color 255,60,0 Else Gray 50

		SetFont comic
		Select i
			Case play
				Text 320,200,"PLAY",1,1
			Case help
				Text 320,260,"HELP",1,1
			Case quit
				Text 320,320,"QUIT",1,1
		End Select
		
		If KeyHit(up) Then s = s - 1
		If KeyHit(down) Then s = s + 1
			
		If s > 2 Then s = 0
		If s < 0 Then s = 2	

		
		If KeyHit(enter) Then
			Select s
				Case play 
					status = ingame
				Case quit
					End
				Case help
					status = readhelp
			End Select 
		EndIf		
	Next
End Function

Function PrintHelp()
	Gray 0
	SetFont smarial
	Text 320,120,"Aim and shoot the balloons with the mouse.",1,1
	Text 320,160,"Look at the launcher at the bottom left hand",1,1
	Text 320,200,"corner of the screen. Try to hit the",1,1
	Text 320,240,"blue stick people's head but",1,1
	Text 320,280,"NOT the red ones.",1,1
	Text 320,320,"You lose 2 points each time you miss",1,1
	Text 320,360,"so click wisely!",1,1
	Text 320,420,"Hit enter to return to main menu",1,1
	
	If KeyHit(enter) Then
		FlushKeys()
		status = menu
	EndIf
End Function 

Function UpdateLauncher()
	dx# = MouseX()
	dy# = MouseY() - 480
	
	angle# = ATan2(dy,dx)
	
	If angle > -40 Then angle = -40
	If angle < -85 Then angle = -85
	
	gundx# = Cos(angle)
	gundy# = Sin(angle)
	
	ex# = gundx*100
	ey# = 480 + gundy*100
	
	Gray 255
	Line -2,478,ex-2,ey-2
	Line 0,480,ex,ey
	Line 2,482,ex+2,ey+2
End Function

Function CreateEnemies()
	f = 0
	For i = 0 To (level+Rand(0,2))-1
		e.enemy = New enemy
		
		e\y = 480-ImageHeight(gfxguy)
		e\x = Rand(140,640-ImageWidth(gfxguy))
		
		e\dx = Rnd#(1,4)
		e\f = f
		If level>2 Then f = Not f
	Next
End Function

Function UpdateAI()
	Local num_e = 0

	For e.enemy = Each enemy
		e\x = e\x + e\dx
		e\y = e\y + e\dy
		
		DrawImage gfxguy,e\x,e\y,e\f
		
		For b.balloon = Each balloon
			If RectsOverlap(b\x,b\y,25,35,e\x,e\y,ImageWidth(gfxguy),e\x+45)
				If e\f Then
					CreateSplash(b\x+12.5,b\y+17.5,b\dy)
					Delete b
					lives = lives - 1
					e\dy = 5
				Else
					CreateSplash(b\x+12.5,b\y+17.5,b\dy)
					score = score + 50 + (level*2) + (Abs(e\dx)*Rand(2,5))
					Delete b
					e\dy = 5
				EndIf
			EndIf
		Next
		
		If Not e\f Then num_e = num_e + 1
		If e\x+ImageWidth(gfxguy) > 640 Or e\x < 140 Then e\dx = -e\dx
		If e\y > 500 Then Delete e
	Next
	
	If num_e <= 0 Then
		level = level + 1
		Delete Each enemy
		CreateEnemies()
	EndIf
End Function

Function DrawHUD()
	SetFont vsmarial
	Color 0,0,0
	Text 15,70,"> Level " + level
	
	If lives < prelives And lives>0 Then
		SetFont arial
		Color 255,0,0:SetBuffer(BackBuffer())
		Text 15,90,"> Lives: " + lives: Flip
		Delay 500
		SetFont vsmarial
	EndIf
	
	Text 15,90,"> Lives: " + lives
	prelives = lives
		
	Color 0,0,0
	Text 15,110,"> Score: " + score
	
	CheckStats()
End Function

Function ResetEverything()
	score = 0
	lives = 5
	level = 0
End Function

Function CheckStats() ;;checks if player is alive
	If lives < 1 Then
		Delete Each balloon
		Delete Each enemy
		Delete Each drop
		
		SetFont comic
		start = MilliSecs()
		status = gameover
	EndIf
End Function 

Function UpdateGameOver()
	If MilliSecs()>start+5000 Then
		ResetEverything()
		status = menu
	Else
		Text 320,200,"GAME OVER",1,1
		Text 320,260,"SCORE: " + score,1,1
	EndIf
End Function 

Function Initialize()
	DrawCloudImage()
	DrawGuy()
	SetBuffer BackBuffer()
	ClsColor 128,255,255 ;;sky blue
	CreateClouds()
End Function


;;subroutines
.Initialize3D
	
	grass = CreateTexture(32,32)
	SetBuffer TextureBuffer(grass)
	;{
		Color 0,200,0
		Rect 0,0,32,32,1
		
		Color 0,160,0
		For x = 0 To 32 Step 2
			For y = 0 To 32 Step 2
				Plot x,y
			Next
		Next
	;}
	SetBuffer BackBuffer()
	
	Global cam = CreateCamera()

	Global plane = CreatePlane()
	EntityTexture plane,grass
	MoveEntity plane,0,-5,0

	Global sky = CreateSphere()
	FlipMesh sky
	ScaleEntity sky,100,100,100
	PositionEntity sky,0,50,0
	EntityColor sky,75,255,255
	
	Global sun = CreateSphere(16)
	MoveEntity sun,18,14,20
	ScaleEntity sun,4,4,4
	EntityColor sun,255,255,0
	EntityShininess sun,1 
	
	AmbientLight 210,210,210	
	Global light = CreateLight(1)
Return