Week 81/Wed. Workshop (SoCoder)

<- Previous Workshop | Next Workshop ->

081 : The "New Year, New Language" Challenge

Date : 27 Dec 2006

Challenge : This week you can make any type of game you want, but you must code it using the new Cobra Demo provided at SqueakyDuck.co.uk

The Entries in order of submission
Missile Command

JL235 | Comments (0) | No Votes

Shoot the missiles from out of the sky.

Mouse

Show Sourcecode for this entry

Hide Sourcecode

// MISSILE COMMAND
// by Joseph Lenton
// 29/12/06

Program
Uses pure2d, keyset

const
    GRAPHICS_WIDTH = 800
    GRAPHICS_HEIGHT = 600
    
    LAND_HEIGHT = 500
    
    BASE_SIZE = 15
    
    PLAYER_MISSILE_SIZE = 3
    PLAYER_MISSILE_SPEED = 4
    PLAYER_MISSILE_COLLISION_OFFSET = 3
    
    MISSILE_SPEED = 3
    MISSILE_SIZE = 3
    MISSILE_RANDOMIZER = 10
    MISSILE_START_ANGLE = 120
    MISSILE_END_ANGLE = 60
    
    EXPLOSION_MAXIMUM_SIZE = 80
    EXPLOSION_SIZE_INCRIMENT = 6

type Bases = record
    x : integer
    y : integer
endtype

type PlayerMissiles = record
    x : real
    y : real
    destinationX : integer
    destinationY : integer
    deltaX : real
    deltaY : real
endtype

type Missiles = record
    x : real
    y : real
    origX : integer
    origY : integer
    deltaX : real
    deltaY : real
endtype

type Explosions = record
    x : integer
    y : integer
    size : integer
endtype 

// draw land
procedure drawLand()
begin
    RectC(0, LAND_HEIGHT, GRAPHICS_WIDTH, GRAPHICS_HEIGHT, ToRGBA(180,60,90), true) 
end

// BASES
// new base
Procedure newBase(x:Integer, y:Integer)
Begin
    base = NewItem(baseList)
    If Assigned(base)
        base.x = x
        base.y = y
    Else 
        MessageBox("Could not add base")
    EndIf
End

// draw bases
procedure drawBases()
begin
    loop base through baseList
        Ellipse(base.x, base.y, BASE_SIZE, BASE_SIZE, ToRGBA(255,255,255), true)
    endloop
end         

// PLAYER MISSILES
// new player missile
procedure newPlayerMissile(x:integer, y:integer, destinationX:integer, destinationY:integer)
var
    angle : real
begin
    playerMissile = newItem(playerMissileList)
    if assigned(playerMissile)
        playerMissile.x = x
        playerMissile.y = y
        playerMissile.destinationX = destinationX
        playerMissile.destinationY = destinationY
        
        angle = atan2(y-destinationY, x-destinationX)
        playerMissile.deltaX = cos(angle)*PLAYER_MISSILE_SPEED
        playerMissile.deltaY = sin(angle)*PLAYER_MISSILE_SPEED
    else
        messagebox("Could not add Player Missile")
    endif
end

// update player missiles
procedure updatePlayerMissiles()
begin
    loop playerMissile through playerMissileList
        playerMissile.x = playerMissile.x-playerMissile.deltaX
        playerMissile.y = playerMissile.y-playerMissile.deltaY
        
        if abs(playerMissile.x-playerMissile.destinationX) < PLAYER_MISSILE_COLLISION_OFFSET
            if abs(playerMissile.y-playerMissile.destinationY) < PLAYER_MISSILE_COLLISION_OFFSET
                newExplosion(playerMissile.x, playerMissile.y)
                free(playerMissile)
            endif
        endif 
    endloop
end

// draw player missiles
procedure drawPlayerMissiles()
begin
    loop playerMissile through playerMissileList
        ellipse(playerMissile.x, playerMissile.y, PLAYER_MISSILE_SIZE, PLAYER_MISSILE_SIZE, torgba(200, 60, 130))
    endloop
end

// MISSILES
// generate new missile
procedure generateNewMissile()
var
    randAngle:integer
    randX:integer
    
begin
    if Rand(0, MISSILE_RANDOMIZER) = 0
        randAngle = Rand(MISSILE_START_ANGLE, MISSILE_END_ANGLE)
        randX = Rand(50, GRAPHICS_WIDTH-50)
         
        newMissile(randAngle, randX, -10)
    endif
end

// new missile
procedure newMissile(angle:integer, x:integer, y:integer)
begin
    missile = newitem(missileList)
    if assigned(missile)
        missile.x = x
        missile.y = y
        missile.origX = x
        missile.origY = y
        
        missile.deltaX = cos(angle)*MISSILE_SPEED
        missile.deltaY = sin(angle)*MISSILE_SPEED 
   Else
        MessageBox("Could not add missile")
   EndIf
end

// draw missiles
procedure drawMissiles()
var
    randColor:integer
    
begin
    loop missile through missileList
        randColor = ToRGBA(Rand(30,225), Rand(30,225), Rand(30,225))
        Line(missile.origX, missile.origY, missile.x, missile.y, randColor)
        Ellipse(missile.x, missile.y, MISSILE_SIZE, MISSILE_SIZE, randColor, true)
    endloop
end

// update missiles
procedure updateMissiles()
begin
    loop missile through missileList
        missile.x = missile.x+missile.deltaX
        missile.y = missile.y+missile.deltaY
        
        if (missile.x < 0) or (missile.x > GRAPHICS_WIDTH) or (missile.y > LAND_HEIGHT)
            free(missile)
        else
            checkMissileBaseCollision(missile)
        endif
    endloop
end

// check missile base collision
procedure checkMissileBaseCollision(localMissile:^Missiles)
begin
    loop base through baseList
        if Abs(base.x-missile.x) < BASE_SIZE/2+MISSILE_SIZE/2
            if Abs(base.y-missile.y) < BASE_SIZE/2+MISSILE_SIZE/2
                free(base)
                free(missile)
                dec(playerLives)
            endif
        endif        
    endloop
end

// EXPLOSION
// new explosion
procedure newExplosion(x:integer, y:integer)
begin
    explosion = newitem(explosionList)
    if assigned(explosion)
        explosion.size = 1
        explosion.x = x
        explosion.y = y
    else
        messagebox("could not make new explosion")
    endif
end

// update explosions
procedure updateExplosions()
var
    x : integer
    y : integer
    
begin
    loop explosion through explosionList
        loop missile through missileList
            x = abs(missile.x-explosion.x)
            y = abs(missile.y-explosion.y)
    
            if sqrt(x*x + y*y) < explosion.size
                free(missile)
            endif
        endloop
        
        explosion.size = explosion.size+EXPLOSION_SIZE_INCRIMENT
        
        if explosion.size > EXPLOSION_MAXIMUM_SIZE
            free(explosion)
        endif
    endloop
end

// draw explosions
procedure drawExplosions()
begin
    loop explosion through explosionList
        ellipse(explosion.x, explosion.y, explosion.size, explosion.size, torgba(255,255,255))
    endloop
end

var
    playerLives : integer
    playerScore : integer
     
    baseList : list of Bases
    base : ^Bases

    playerMissileList : list of PlayerMissiles
    playerMissile : ^PlayerMissiles
    
    missileList : list of Missiles
    missile : ^Missiles
    
    explosionList : list of Explosions
    explosion : ^Explosions
    
    i : integer

Begin 
    OpenScreen(GRAPHICS_WIDTH, GRAPHICS_HEIGHT, 16, False)
    
    playerLives = 5
    
    for i = 1 to playerLives
        newBase(rand(50, GRAPHICS_WIDTH-50), LAND_HEIGHT)
    next   
    
    // main loop
    While (keydown(1)=0) and (playerLives > 0)
        if mousehits(0) > 0
            newPlayerMissile(0, LAND_HEIGHT, mousex(), mousey())
        endif
        if mousehits(1) > 0
            newPlayerMissile(GRAPHICS_WIDTH, LAND_HEIGHT, mousex(), mousey())
        endif
        
        // update everything
        updatePlayerMissiles
        updateExplosions
        generateNewMissile
        updateMissiles
           
        // draw everything
        Cls
        drawLand
        drawExplosions
        drawMissiles
        drawPlayerMissiles
        drawBases
        
        playerScore = playerScore+1
        pencolor(toRgba(255,255,255))
        Text(10, 52, "Score: "+playerScore)
        text(10, 64, "Lives: "+playerLives)
        Flip
    Wend
    
    messagebox("You Scored: " + playerScore)
    CloseScreen
End

The Really Stupid Ball Bouncing Game

Jayenkai | Comments (0) | No Votes

Bounce the ball down the path.

Cursors

Show Sourcecode for this entry

Hide Sourcecode

Program
Uses Pure2d, Keyset

Var
    x,y,n:integer  
    mx,mt:integer
    mt2:integer    
    tick:integer
    speed:integer 
    ballx:integer   
    Heart:integer
    bally,bounce:real 
    score:integer  
    sx,ex:integer      
    endofgame:integer
    offset : array[100000,2] of integer                 
    col:array[100000,6] of integer    
    ballx2:array[500] of integer

Begin
    OpenScreen(800, 600)
mx=300
endofgame=0
mt=1
Speed=1
Tick=0
mt2=rand(0-Speed,Speed)   

ballx=400
bally=600
bounce=0
Score=0
Heart=5

for x=1 to mx
for y=1 to 3
col[x,y]=180
col[x,y+3]=1
next
next

    Repeat   
        CLS( torgba(40,80,160))
                 
            for x=1 to mx-1
                for y=1 to 3
                    col[x,y]=col[x+1,y]
                    if x<70 then col[x,y]=col[x+4,y]
                    if x<140 then col[x,y]=col[x+3,y]
                    if x<210 then col[x,y]=col[x+2,y]
                    
                next                                       
                y=1
                offset[x,y]=offset[x+1,y] 
                if x=mx-1 then offset[x,y]=offset[x,y]+rand(-2,2)
                    if x<70 then offset[x,y]=offset[x+4,y]
                    if x<140 then offset[x,y]=offset[x+3,y]
                    if x<210 then offset[x,y]=offset[x+2,y]
                                      
            next  
             
tick=tick+1
if tick>250 then tick=0; speed=speed+1
score=score+1

                           
             bounce=bounce+4
             bally=600-abs(sin(bounce)*50) 
             if bounce>176 
                bounce=0                    
             endif
                if keydown(VK_Left) then ballx=ballx-2
                if keydown(VK_Right) then ballx=ballx+2  
                
            x=mx                
                for y=1 to 3
                col[x,y]=col[x,y]+col[x,y+3]
                if col[x,y]>180 then col[x,y+3]=Rand(-4,1)
                if col[x,y]<100 then col[x,y+3]=Rand(1,4)   
                if rand(1,10)=1 then col[x,4]=rand(-4,4)
                next                         
                
                offset[x,1]=offset[x,1]+mt2
                if offset[x,1]<-250 then offset[x,1]=-250; mt2=2
                if offset[x,1]>250 then offset[x,1]=250; mt2=-2
                if (rand(1,30)=1) and (offset[x,1]<100) then mt2=rand(0,speed)
                if (rand(1,30)=1) and (offset[x,1]>-100) then mt2=rand(0-speed,0)

            for x=0 to mx   
            sx=(400-offset[x,1])-((mx-x)/3)
            ex=(400-offset[x,1])+((mx-x)/3)
                line (0,(300-offset[x,2])+((mx-x)*mt),800,(300-offset[x,2])+((mx-x)*mt), ToRGBA(col[x,1]-80,col[x,1],col[x,1]-80))     
                line (sx,(300-offset[x,2])+((mx-x)*mt),ex,(300-offset[x,2])+((mx-x)*mt), ToRGBA(col[x,1]+40,col[x,1]+20,col[x,1]))
                if (x=5) and (bounce=0)             
                    if (ballx<sx) then heart=heart-1
                    if (ballx>ex) then heart=heart-1
                endif 
            next
                  
ballx2[1]=ballx
for n=250 to 2 step -1
ballx2[n]=ballx2[n-1]
next
for n=1 to heart              
        ellipse (ballx2[((n-1)*25)+1],600-abs(sin(bounce+(n*25))*50),20,20,torgba(255-(n*25),0,0),1)
next

            pencolor(torgba(0,0,0))
            text (400,200,"Distance "+score)
            if heart=0 then endofgame=1                            
            
        Flip          
        if keydown(VK_Escape) then endofgame=99
    Until endofgame<>0
                      
    
    pause (1500)          
    
    CloseScreen
End

SHUMP

magicman | Comments (0) | No Votes

A shoot-em-up made in Cobra

Cursors and Spacebar

Click to Download this entry.

Cobra-oids

grahamk | Comments (1) | No Votes

Shoot all the rocks!

Cursors and Spacebar

Show Sourcecode for this entry

Hide Sourcecode

Program
Uses Pure2d, Keyset

Var
    x,y,n:integer  
    mx,mt:integer
    mt2:integer    
    tick:integer
    speed:integer 
    ballx:integer   
    Heart:integer
    bally,bounce:real 
    score:integer  
    sx,ex:integer      
    endofgame:integer
    offset : array[100000,2] of integer                 
    col:array[100000,6] of integer    
    ballx2:array[500] of integer

Begin
    OpenScreen(800, 600)
mx=300
endofgame=0
mt=1
Speed=1
Tick=0
mt2=rand(0-Speed,Speed)   

ballx=400
bally=600
bounce=0
Score=0
Heart=5

for x=1 to mx
for y=1 to 3
col[x,y]=180
col[x,y+3]=1
next
next

    Repeat   
        CLS( torgba(40,80,160))
                 
            for x=1 to mx-1
                for y=1 to 3
                    col[x,y]=col[x+1,y]
                    if x<70 then col[x,y]=col[x+4,y]
                    if x<140 then col[x,y]=col[x+3,y]
                    if x<210 then col[x,y]=col[x+2,y]
                    
                next                                       
                y=1
                offset[x,y]=offset[x+1,y] 
                if x=mx-1 then offset[x,y]=offset[x,y]+rand(-2,2)
                    if x<70 then offset[x,y]=offset[x+4,y]
                    if x<140 then offset[x,y]=offset[x+3,y]
                    if x<210 then offset[x,y]=offset[x+2,y]
                                      
            next  
             
tick=tick+1
if tick>250 then tick=0; speed=speed+1
score=score+1

                           
             bounce=bounce+4
             bally=600-abs(sin(bounce)*50) 
             if bounce>176 
                bounce=0                    
             endif
                if keydown(VK_Left) then ballx=ballx-2
                if keydown(VK_Right) then ballx=ballx+2  
                
            x=mx                
                for y=1 to 3
                col[x,y]=col[x,y]+col[x,y+3]
                if col[x,y]>180 then col[x,y+3]=Rand(-4,1)
                if col[x,y]<100 then col[x,y+3]=Rand(1,4)   
                if rand(1,10)=1 then col[x,4]=rand(-4,4)
                next                         
                
                offset[x,1]=offset[x,1]+mt2
                if offset[x,1]<-250 then offset[x,1]=-250; mt2=2
                if offset[x,1]>250 then offset[x,1]=250; mt2=-2
                if (rand(1,30)=1) and (offset[x,1]<100) then mt2=rand(0,speed)
                if (rand(1,30)=1) and (offset[x,1]>-100) then mt2=rand(0-speed,0)

            for x=0 to mx   
            sx=(400-offset[x,1])-((mx-x)/3)
            ex=(400-offset[x,1])+((mx-x)/3)
                line (0,(300-offset[x,2])+((mx-x)*mt),800,(300-offset[x,2])+((mx-x)*mt), ToRGBA(col[x,1]-80,col[x,1],col[x,1]-80))     
                line (sx,(300-offset[x,2])+((mx-x)*mt),ex,(300-offset[x,2])+((mx-x)*mt), ToRGBA(col[x,1]+40,col[x,1]+20,col[x,1]))
                if (x=5) and (bounce=0)             
                    if (ballx<sx) then heart=heart-1
                    if (ballx>ex) then heart=heart-1
                endif 
            next
                  
ballx2[1]=ballx
for n=250 to 2 step -1
ballx2[n]=ballx2[n-1]
next
for n=1 to heart              
        ellipse (ballx2[((n-1)*25)+1],600-abs(sin(bounce+(n*25))*50),20,20,torgba(255-(n*25),0,0),1)
next

            pencolor(torgba(0,0,0))
            text (400,200,"Distance "+score)
            if heart=0 then endofgame=1                            
            
        Flip          
        if keydown(VK_Escape) then endofgame=99
    Until endofgame<>0
                      
    
    pause (1500)          
    
    CloseScreen
End

<- Previous Workshop | Next Workshop ->