SoCoder - Blog - PCRobots

Created 13 November 2006 | Last Edited 02 February 2009

PCRobots
A programming game

When I was working as a Software Engineer back in the 90's, I remember having a whole lotta fun (during smoko breaks etc) writing PCRobots to compete with those written by my co-workers.

Unfortunately, some of my less scrupulous, "hacker" colleagues soon figured out how to circumvent the official PCRobots API by directly accessing live data structures in memory, which of course gave their bots a very unfair advantage! I did actually toy with the idea of rewriting PCRobots in protected-mode at the time, which would have prevented this kind of insidious cheating, but alas I never got around to it.

Now that I have the time, I'd like to do a remake of PCRobots. Unlike the original, however, it will be cross-platform (Windows, Mac OS X, Linux) and it will be a multiplayer, networked application - i.e. instead of the main PCRobots application loading all the bots into memory as individual tasks (and communicating with them via DOS software interrupts) each bot will run as a completely separate program, communicating with the PCRobots "server" via UDP packets.
The server itself can run either on the same local machine as the bots, or on a remote host.

I intend to code it in C and use Allegro or SDL for graphics/sound, with perhaps Gnet or Enet for networking. Blitz Max is also a possibility; perhaps I'll prototype it in BMax and then port it to C.

At this stage I plan to provide API wrappers that will allow bots to be written in Blitz Basic (via DLL userlib), Blitz Max, PureBasic or C.
Initially, the graphics will be identical to the original DOS version, but once I get the basic engine working, I'll of course soup it up with better sprites and sound effects, etc.

Later, I might try upgrading the graphics to a full 3D version, with the bots perhaps represented as battle tanks. The user will be able to enter the arena and observe the bots doing battle, rather like in Counter Strike after you have been killed. I guess actually using the Source Engine is a possibility too, but that's quite a way down the track at this stage.

The API will, for the most part, be identical to the original PCRobots API. This will enable bots originally written for the DOS version to be easily ported (some of which will be included as examples).

Maybe if there's enough interest, we can hold a PCRobots Tournament as a Wednesday Workshop or something

31 Dec '06
I think I'll use this blog as my worklog, at least until I have something ready to post in the Showcase section.

I'm coding it in BlitzMax, just to see how that goes. At first, I considered just porting most of Paul Smith's original C++ code, but instead I decided to start from scratch with a new architecture of my own design. The C++ source is mostly DOS-specific, which of course I don't need. Nevertheless, I'm extracting as much of the original code as is necessary to faithfully reproduce the functionality of the original DOS version.

Completed so far:
* All graphics (screen resolution independent)
* Arena class and Map file loader
* Robot class
* Some of the API

Next:
* Cannon class
* Complete API & test all functions
* Produce .ogg files from original DOS sound effects

The plan is to test the API with "internal" robot mini-programs and then, after everything checks out, implement the network feature. I'm looking at using either GNet/Enet (which is directly supported in BlitzMax) or Krylar's K-NetLib.

At this stage, K-NetLlib looks like it might be the better option, because it's directly supported by PureBasic and also Cobra. Because BlitzMax can't be used to build DLL's for Windows, I plan to use PureBasic to implement the client APIs. PureBasic is also cross-platform, so I should be able to use most of the same code for the Mac and Linux plug-ins.

And, courtesy of Filax's K-NetLib module for BlitzMax, I'll be able to use it for the PCRobots Server application as well.

26 Feb '07

Well, everything was going quite well with Blitz Max until I tried to run it under Windows 98 on my old laptop (a 133MHz Pentium). The graphics were all screwed up, and it ran incredibly slow. Why should it be so bloated and slow compared to the original DOS version? My Blitz Max code certainly isn't inefficient - in fact I took great pains to write quite optimal code.

Anyway, the upshot of it is that I've become dissatisfied with the limitations of Blitz Max, so I've decided to recode the whole thing in D - using SDL to handle the graphics, sound and keyboard input, etc. It was always my long term plan to migrate to D as my primary language, and now that a stable Version 1.0 has recently been released by Digital Mars, I may as well take the plunge.

So, apologies for the delay, but it'll take a little while longer for me to learn D and also get familiar with the SDL API.
Stay tuned, I promise PCRobots v2 will happen, eventually...

24 May '08
Still experimenting with various languages and libraries in order to determine the best solution for cross-platform implementation.

In the meantime, here's some code I've written that might be useful to any Forth programmers out there who are interested in having a play with the DOS version of PCRobots.

0 [IF]

  ROBOTS1.4TH
  
  PCRobots library declarations for ForthCMP
   by Agent Smith, May 2008

  Include this file at start of Robot program
  Include ROBOTS2 before FORTHLIB

[THEN]

DECIMAL

\ Values returned by GET-LOCAL-MAP
 0 CONSTANT ARENA-FREE
 1 CONSTANT ARENA-WALL
 3 CONSTANT ARENA-DAMAGE
30 CONSTANT ARENA-REFUEL 

\ Values returned by SHELL-STATUS?
 0 CONSTANT SHELL-MISSED
 1 CONSTANT SHELL-HIT-WALL
 2 CONSTANT SHELL-CLOSE-BLAST
 3 CONSTANT SHELL-NEAR-MISS
 4 CONSTANT SHELL-DIRECT-HIT
 5 CONSTANT SHELL-NOT-KNOWN
 6 CONSTANT SHELL-IN-FLIGHT

\ Forward references
0 0 IN/OUT NEED SWAP-TASK
2 0 IN/OUT NEED MOVE
2 2 IN/OUT NEED SCAN
2 1 IN/OUT NEED SHOOT
0 2 IN/OUT NEED GET-XY
2 1 IN/OUT NEED TRANSMIT
0 2 IN/OUT NEED RECEIVE
0 1 IN/OUT NEED ARMOUR
0 1 IN/OUT NEED SPEED
0 1 IN/OUT NEED BATTERY
0 2 IN/OUT NEED #TICKS
1 2 IN/OUT NEED SIN
1 2 IN/OUT NEED COS
1 2 IN/OUT NEED TAN
2 1 IN/OUT NEED ATAN
2 2 IN/OUT NEED SQRT
1 0 IN/OUT NEED SET-PATTERN
2 0 IN/OUT NEED DEBUG-FLAG
1 0 IN/OUT NEED BUY-ARMOUR
1 0 IN/OUT NEED BUY-SHELLS
0 1 IN/OUT NEED #SHELLS
1 0 IN/OUT NEED GET-LOCAL-MAP
1 0 IN/OUT NEED INVISIBILITY
0 1 IN/OUT NEED SHELL-STATUS?
0 1 IN/OUT NEED INVISIBLE?
2 1 IN/OUT NEED ATAN2              
0 1 IN/OUT NEED ID
1 0 IN/OUT NEED REGISTER-IFF
1 1 IN/OUT NEED IFF?
1 0 IN/OUT NEED REGISTER-NAME
2 1 IN/OUT NEED FIND-NAME
0 1 IN/OUT NEED TEAM-ID
1 1 IN/OUT NEED THIS-SHELL-STATUS?
1 1 IN/OUT NEED REGISTER-X
1 1 IN/OUT NEED REGISTER-Y

0 [IF]

  ROBOTS2.4TH
  
  PCRobots library functions for ForthCMP
   by Agent Smith, May 2008

  Include ROBOTS1 at start of Robot program
  Include this file before FORTHLIB

[THEN]

CR .( Loading PCRobots )
10 HEX
     
UNDEF SWAP-TASK
  CODE SWAP-TASK ( -- ) 
    AX AX XOR
    E0 INT 
    RET
  END-CODE
[THEN]

UNDEF MOVE
  CODE MOVE ( speed angle -- )
    CX AX XCHG
    1 # AX MOV
    E0 INT
    RET
  END-CODE
[THEN]

UNDEF SCAN  
  CODE SCAN ( angle resolution -- range id|-1 )
    CX AX XCHG
    2 # AX MOV
    E0 INT
    RET
  END-CODE
[THEN]  

UNDEF SHOOT
  CODE SHOOT ( angle range -- flag )
    CX AX XCHG
    3 # AX MOV
    E0 INT
    RET    
  END-CODE 
[THEN]

UNDEF GET-XY
  CODE GET-XY ( -- x y )
    10 # AX MOV
    E0 INT
    AX CX XCHG
    RET
  END-CODE
[THEN]   
 
UNDEF TRANSMIT 
  CODE TRANSMIT ( target data -- flag )
    CX AX XCHG
    11 # AX MOV
    E0 INT    
    RET
  END-CODE 
[THEN]

UNDEF RECEIVE   
  CODE RECEIVE ( -- data source|-1 )
    12 # AX MOV
    E0 INT
    AX AX TEST
    =0 IF,
      AX DEC
      RET
    THEN,
    AX BX XCHG
    BX CX XCHG
    RET
  END-CODE
[THEN]   

UNDEF ARMOUR
  CODE ARMOUR ( -- #units )
    13 # AX MOV
    E0 INT
    AX BX XCHG 
    RET
  END-CODE
[THEN]     
 
UNDEF SPEED
  CODE SPEED ( -- speed )
    14 # AX MOV
    E0 INT
    AX BX XCHG
    RET
  END-CODE 
[THEN]
 
UNDEF BATTERY 
  CODE BATTERY ( -- charge )
    15 # AX MOV
    E0 INT
    AX BX XCHG
    RET
  END-CODE
[THEN]   

UNDEF #TICKS
  CODE #TICKS ( -- ud )
    16 # AX MOV
    E0 INT
    AX BX XCHG
    BX CX XCHG
    RET
  END-CODE
[THEN]   

UNDEF SIN 
  CODE SIN ( angle -- d )
    BX AX XCHG
    17 # AX MOV
    E0 INT
    AX BX XCHG
    BX CX XCHG
    RET    
  END-CODE
[THEN]   

UNDEF COS
  CODE COS ( angle -- d )
    BX AX XCHG
    18 # AX MOV
    E0 INT
    AX BX XCHG
    BX CX XCHG
    RET    
  END-CODE
[THEN]   

UNDEF TAN
  CODE TAN ( angle -- d )
    BX AX XCHG
    19 # AX MOV
    E0 INT
    AX BX XCHG
    BX CX XCHG
    RET
  END-CODE
[THEN]   

UNDEF ATAN
  CODE ATAN ( d -- angle )
    CX BX XCHG
    BX AX XCHG
    1A # AX MOV
    E0 INT
    RET
  END-CODE
[THEN]   

UNDEF SQRT
  CODE SQRT ( d -- d' )
    CX BX XCHG
    BX AX XCHG
    1B # AX MOV
    E0 INT
    AX BX XCHG
    BX CX XCHG
    RET    
  END-CODE
[THEN]   

UNDEF SET-PATTERN
  CODE SET-PATTERN ( addr -- )
    BX DS <SEG
    CX AX XCHG
    1C # AX MOV
    E0 INT
    RET
  END-CODE
[THEN]   

UNDEF DEBUG-FLAG
  CODE DEBUG-FLAG ( 0|1 flag -- )
    1 # AX AND
    CX AX XCHG
    1D # AX MOV
    E0 INT
    RET
  END-CODE
[THEN]   

UNDEF BUY-ARMOUR
  CODE BUY-ARMOUR ( #units -- )
    BX AX XCHG
    1E # AX MOV
    E0 INT
    RET
  END-CODE
[THEN]

UNDEF BUY-SHELLS
  CODE BUY-SHELLS ( #shells -- )
    BX AX XCHG
    1F # AX MOV
    E0 INT
    RET
  END-CODE
[THEN]   

UNDEF #SHELLS
  CODE #SHELLS ( -- #shells )
    20 # AX MOV
    E0 INT
    AX BX XCHG
    RET
  END-CODE
[THEN]   

UNDEF GET-LOCAL-MAP
  CODE GET-LOCAL-MAP ( addr -- )
    BX DS <SEG
    CX AX XCHG
    21 # AX MOV
    E0 INT
    RET
  END-CODE 
[THEN]

UNDEF INVISIBILITY
  CODE INVISIBILITY ( flag -- )
    1 # AX AND
    BX AX XCHG
    22 # AX MOV
    E0 INT
    RET
  END-CODE
[THEN]   

UNDEF SHELL-STATUS?
  CODE SHELL-STATUS? ( -- status )
    23 # AX MOV
    E0 INT
    AX BX XCHG
    RET
  END-CODE
[THEN]

UNDEF INVISIBLE?
  CODE INVISIBLE? ( -- flag )
    24 # AX MOV
    E0 INT
    AX BX XCHG    
    RET
  END-CODE
[THEN]   

UNDEF ATAN2
  CODE ATAN2 ( y x -- n )
    CX AX XCHG
    25 # AX MOV
    E0 INT
    RET
  END-CODE
[THEN]   

UNDEF ID
  CODE ID ( -- id )
    26 # AX MOV
    E0 INT
    RET
  END-CODE 
[THEN]

UNDEF REGISTER-IFF
  CODE REGISTER-IFF ( addr -- )
    BX DS <SEG
    CX AX XCHG
    27 # AX MOV
    E0 INT
    RET
  END-CODE 
[THEN]

UNDEF IFF?
  CODE IFF? ( id -- flag )
    BX AX XCHG
    28 # AX MOV
    E0 INT
    RET
  END-CODE 
[THEN]

UNDEF REGISTER-NAME
  CODE REGISTER-NAME ( addr -- )
    BX DS <SEG
    CX AX XCHG
    29 # AX MOV
    E0 INT
    RET
  END-CODE
[THEN]   

UNDEF FIND-NAME
  CODE FIND-NAME ( addr start -- id|-1 )
    DX AX XCHG
    CX BX XCHG
    BX DS <SEG
    2A # AX MOV
    E0 INT
    RET
  END-CODE
[THEN]

UNDEF TEAM-ID
  CODE TEAM-ID ( -- id|-1 )
    2B # AX MOV
    E0 INT
    RET
  END-CODE
[THEN]  

UNDEF THIS-SHELL-STATUS?
  CODE THIS-SHELL-STATUS? ( id -- status )
    BX AX XCHG
    2C # AX MOV
    E0 INT
    RET
  END-CODE
[THEN]   

UNDEF REGISTER-X
  CODE REGISTER-X ( addr -- flag )
    BX DS <SEG
    CX AX XCHG
    2D # AX MOV
    E0 INT    
    RET
  END-CODE
[THEN]

UNDEF REGISTER-Y
  CODE REGISTER-Y ( addr -- flag )
    BX DS <SEG
    CX AX XCHG
    2E # AX MOV
    E0 INT  
    RET
  END-CODE
[THEN]   

2 1 IN/OUT
CODE (configure) ( BX CX -- 0|version )
  CX AX XCHG
  80 # AX MOV
  E0 INT  
  RET
END-CODE

: CONFIGURE 
  \ speed manoeuvre range armour
  \ acceleration invisibility -- 0|version
  1 AND 3 LSHIFT SWAP 
  7 AND OR >R
  F AND C LSHIFT SWAP
  F AND 8 LSHIFT OR SWAP
  F AND 4 LSHIFT OR SWAP
  F AND OR R>  
  (configure) 
;

0A = [IF] DECIMAL [THEN]

0 [IF]

  RANDOM.4TH

  Pseudo-random number generator for ForthCMP
   by Agent Smith, May 2008

[THEN]

CR .( Loading RANDOM )
10 HEX

7FFF CONSTANT RAND-MAX

2VARIABLE next  1 S>D next 2!

PRIMITIVE
CODE D* ( d1 d2 -- d3 )
  DI POP
  CX POP BX POP
  DX POP AX POP
  AX SI MOV
  AX DX XCHG
  AX AX TEST
  =0 ~ IF,
    BX MUL
  THEN,
  AX CX XCHG
  AX AX TEST
  =0 ~ IF,
    SI MUL
    AX CX ADD
  THEN,
  AX SI XCHG  
  BX MUL
  CX DX ADD
  AX PUSH DX PUSH             
  DI JMPI
END-CODE

0 2 IN/OUT
: TIMER ( -- ud )  0 46C 2@L SWAP ;

1 0 IN/OUT
: SRAND ( u -- )  S>D next 2! ;

0 1 IN/OUT                     
: RAND ( -- u )
  next 2@ 4E6D 41C6 D* 3039 M+ TUCK
  next 2! RAND-MAX AND 
;

1 1 IN/OUT
: RANDOM ( u -- u' )  RAND SWAP MOD ;

0 0 IN/OUT
: RANDOMIZE ( -- )  TIMER next 2! ;
  
0A = [IF] DECIMAL [THEN]

The following Forth program is a port of P.D.Smith's "Simple" demonstration Robot (C and Pascal versions were included in the original PCRobots package). It compiles to a .COM executable, 525 bytes in size.

0 [IF]

  SIMPLE.4TH

  ForthCMP version of P.D.Smith's "Simple" robot

[THEN]

100 MSDOS

INCLUDE RANDOM
INCLUDE ROBOTS1

5 CONSTANT RESOLUTION

\ Define possible angles of motion
  ( X Y are x,y positions on the local map )
CTABLE X  5 C, 5 C, 4 C, 3 C, 3 C, 3 C, 4 C, 5 C,
CTABLE Y  4 C, 5 C, 5 C, 5 C, 4 C, 3 C, 3 C, 3 C,
 
\ Buffer to hold local map
9 9 * CARRAY LOCAL-MAP

VARIABLE DIRECTION  ( 0..7 )   


0 1 IN/OUT
: BEARING ( -- u , angle in degrees )  
\ Get a map of the local area
  0 LOCAL-MAP GET-LOCAL-MAP
\ Look for a square that hasn't got a wall in it
  ( ignore traps in this simple program )
  DIRECTION @
  BEGIN
    DUP Y SWAP
    DUP X ROT
    9 * + LOCAL-MAP C@
  ARENA-WALL = WHILE
    DROP 8 RANDOM
  REPEAT
  DUP DIRECTION !
  45 * 
;  


: MAIN
  RANDOMIZE
  8 RANDOM DIRECTION !         \ Select initial direction
  0                            \ Select initial scan angle

\ Note - this is an *INFINITE* loop
  ( the PCROBOTS executive program kills off the robot )
  BEGIN
    50 BEARING MOVE            \ Move in the new direction
    DUP DUP RESOLUTION
    SCAN 0 >= IF               \ Check if target found
      SHOOT DROP               \ shoot at it if so,
    ELSE 2DROP
      RESOLUTION + 360 MOD     \ otherwise go to next angle
    THEN  
  AGAIN 
;


INCLUDE ROBOTS2
INCLUDE FORTHLIB

END

Note - the main PCRobots website seems to have gone offline, but its archive can still be accessed via the Wayback Machine: here

23 Nov '08
Hmm... after taking some time to learn and play around with the D and eC languages a bit, I've decided that I might give Blitz Max another shot.

After all, I never really bothered to investigate just why my original code was so sluggish � it could well be just that my way of using the API was inefficient. On reflection, there's probably no good reason to jettison the code I've already written; especially since any speed bottleneck is likely to be localized and can thus be easily optimized with C or even assembly language, if necessary. So then, back to Blitz Max it is

3 Feb '09
Arrgh! Still no progress. Will I ever get this project finished?
Now I'm thinking "to hell with Blitz Max". D+SDL is where I really want to be.

Latest Comments

Posted : Monday, 13 November 2006, 22:23

hyruleknight

cool, i will help if i can. i have a PC that you can use as a linux server

as long as the program for the server does not use any graphics when running it will run fine as a test server with a little RAM upgrade

Posted : Monday, 13 November 2006, 22:37

Agent

Thanks, hyrule. I'd appreciate any help.

Actually, what I had intended was that the server would be the one with the graphics, so you can see what's happening with all bots, with the bot programs not having any graphics.

But I suppose it can be flexible; the server could just be a CLI app which dumps the results into a text file or something.
And I guess it won't be much fun running your bot remotely and not being able to see what's going on.

But the thing is, the Server knows where all the bots are, whereas individual bots only know their own position, plus the location of any nearby enemy bots that they're able to detect using their scanners.

Posted : Monday, 13 November 2006, 23:12

hyruleknight

hmm, well since only i would see what the server's output would be you should only focus on the server outputing text for debugging and get the UDP packets flying out of it

also my home is on a highspeed connection with a wireless network.

and planning this would go a lot faster in the gabbly chat

Posted : Monday, 13 November 2006, 23:25

Agent

Sure thing, but the idea with the server program is that it can also be run on the same machine (with graphics) as your bot.
This is so you can test, tweak and perfect your bot before unleashing it in the official tournament

Posted : Monday, 13 November 2006, 23:34

hyruleknight

but then it is not a server mode but a test mode. the actual server will have no interaction with a user besides debugging and there fore would not need graphics

Posted : Sunday, 03 December 2006, 10:34

slobbit

Agent Smith, good luck with the project and I really hope that you complete it. I too got hooked by the game in the mid 1990s, more than any other computer game that I have played before or since.

Incidentally, I recently got the original DOS PCRobots running on my PC under DosBox and it brought back all the memories!

The biggest site I have found with example robots is the University of Frankfurt:
http://www.informatik.uni-frankfurt.de/~hbecker/pcrob.html

Posted : Sunday, 03 December 2006, 13:02

Agent

Thanks, slobbit. Great to hear that there are still other PCRobots fans out there

My PCRobots remake will definitely be completed, but atm it's No. 2 in the queue. I'm just prepping an article for post first, then I'll clear my desk and it'll be full steam ahead.

Yes, I was aware of that site you mentioned (link in my blog) which appears to be the main PCRobots website and repository for PCRobots exe's.
A while ago I also searched for PCRobots tournaments, but wasn't able to find any still being run.

I'd be interested in the source code for any of your own PCRobots, if you still have them and wouldn't mind sharing. But I'll understand if you don't want to reveal your secret algorithms (for potential use in future tournament entries).

I've also got the original PCRobots running on DOSBox under OS X on my Mac

Posted : Monday, 04 December 2006, 14:44

slobbit

I am happy to provide source code for one of my robots (not the best, I am keeping that for later!) and a few others, including the strong "Tilly" robot.

I used to compile my own robots with Borland Turbo C++ which is now available free of charge (as is Turbo Pascal) from:
http://bdn.borland.com/museum/

Let me know how to send the files to you.

Posted : Monday, 04 December 2006, 15:58

Agent

That would be much appreciated if you could email it to me.

Is your Tilly by the same author as Tilly_9 (#8 from the website)?
So far I have the sources for Simple, Demo, Explorer, Gamma, Si2, and Termis - all of which I will port and include as examples with my remake.

I also used to program my bots in Turbo C, but I switched to DeSmet C because it generated smaller .exe's, allowing a larger program
(a "do nothing" null program in DeSmet C is only about 1.5k in size). I also did an API so I could use Janus/Ada 83.

Posted : Tuesday, 05 December 2006, 11:25

slobbit

I have just sent you source code for the following:

Tilly v1 to v9 (Tilly9 came 8th in the competition)
Slime (40th in the competition)
Control (one of mine)
Snark0 (another of mine)

Apart from my own robots and those you already have, these are all the source codes that I have available.

Posted : Tuesday, 05 December 2006, 14:07

Agent

(slobbit)
I've sent you an email reply already, but thanks again for providing me with the source code for some particularly strong robots.

(others)
slobbit is actually none other than the author of PCRobots Competition winning entry "Snark1b"

Posted : Saturday, 25 August 2007, 03:43

slobbit

Agent Smith, I hope that you are having more luck with the PCRobots rewrite in D.

I fired up DOSBox a couple of times recently and made some improvements to my old Turbo C++ robot. Now I just need an opponent!

I have taken a look at RoboCode, but the game is not as deep. A RoboCode robot dodges bullets by moving from side to side. A PCRobots robot dodges shells, requiring prediction and movement in two dimensions.

When the time comes, if you need a tester then please let me know.

Posted : Sunday, 26 August 2007, 15:44

Agent

Sorry I haven't been able to get it finished yet, unfortunately the real world keeps monopolizing my limited hobby time. The project is progressing (albeit slowly) so please stay tuned.

I hadn't heard of RoboCode and I'm not a Java programmer, but I'll have a play with it anyway. I know there are a number of similar games out there; maybe they'll give me some ideas for future PCRobots improvements.

Thanks for the offer to test, I'll be sure to send you a Beta version to try out as soon as it's ready.

Posted : Sunday, 26 August 2007, 20:43

Nolan

I remember RoboCode from way back when I began programming. Good fun!

I'm really looking forward to seeing this project progress, Agent Smith.