Soft Body Physics/Code Snippet (SoCoder)

Code Snippets > Collisions and Physics (

Created 12 September 2010 | Last Edited 12 September 2010)

Soft Body Physics by Scherererer | No Votes
Simple demo of roughly how soft bodies work

This demo is very rudimentary, but basically it demonstrates kind of how soft bodies work. The basic idea is to pretend that the lines connecting vertices have on them a spring and a damper. Then, when a force is exerted on some point (or series of points), that force can be reflected across the other points.

More points means more realistic looking surfaces.

Spring coefficient [0,1]: higher number->more spring, lower number->less spring

Damping coefficient [0,1]: higher number->more damping; not to be confused with less springyness.

"spring" resists displacement, whereas "damping" resists change in displacement (velocity).

The forces applied effect the change in the change in displacement (change in velocity (acceleration))

See Calculus:

erivatives and Wikipedia: Damping for more on this.

The spring/dampers in this example are only connected along the square "grid" lines, however in typical/modern configurations, additional connections are made on the diagonals and over other points to compensate for polygon folding and other issues.

Const Mass = 1
Const K# = .5
Const Cd# = .5;.8
Global F1# = 2, F2# = 1

Const dt# = .1

Graphics3D 800,600,32,2

Type Vertex
	Field v
	Field x#, y#, z#
	Field xd#, yd#, zd#
	Field xdd#, ydd#, zdd#
End Type

m=CreateMesh()
s=CreateSurface( m )
Dim verts.Vertex(4,5)

i=0
For r=0 To 3
	For c=0 To 4
		verts(r,c) = New Vertex
		verts(r,c)\x = r
		verts(r,c)\y = c
		
		AddVertex s, r, c, 0
		verts(r,c)\v = i
		
		VertexColor s, verts(r,c)\v, Rnd(0,255), Rnd(0,255), Rnd(0,255)
		
		i = i + 1
	Next
Next


For r=0 To 2
	For c=0 To 3
		AddTriangle s, verts(r,c)\v, verts(r,c+1)\v, verts(r+1,c+1)\v
		AddTriangle s, verts(r,c)\v, verts(r+1,c+1)\v, verts(r+1,c)\v
	Next
Next

EntityFX m, 2

light = CreateLight(2)

camera = CreateCamera()
MoveEntity camera, -.1, -.1, -3
TurnEntity camera, -20, -20, 0

While (Not KeyDown(1))
	
	For r=1 To 2
		For c=1 To 3
			v.Vertex = verts(r,c)
			v\xdd = K*(DiplacementX#(r, c)) + Cd*(DiplacementXD#(r, c))
			v\ydd = K*(DiplacementY#(r, c)) + Cd*(DiplacementYD#(r, c))
			v\zdd = K*(DiplacementZ#(r, c)) + Cd*(DiplacementZD#(r, c))
			
			If (c = 2 And r = 1)
				v\zdd = v\zdd + F1
			EndIf
			
			If (c = 2 And r = 2)
				v\zdd = v\zdd + F2
			EndIf
			
			v\xd = v\xd + v\xdd*dt
			v\yd = v\yd + v\ydd*dt
			v\zd = v\zd + v\zdd*dt
			
			v\x = v\x + (v\xd)*dt
			v\y = v\y + (v\yd)*dt
			v\z = v\z + (v\zd)*dt
			
			VertexCoords s, v\v, v\x, v\y, v\z
		Next
	Next
	
	If (KeyDown(200))
		F1 = F1 + .1
	ElseIf (KeyDown(208))
		F1 = F1 - .1
	EndIf
	
	UpdateWorld
	RenderWorld
	
	Text 0,00,"Force 1: " + F1
	Text 0,13,"Force 2: " + F2
	Text 0,26,"Spring Coeff: " + K
	Text 0,39,"Damping Coeff: " + Cd
	
	VWait : Flip False
Wend

Function DiplacementX#(r%, c%)
	Return verts(r+1,c)\x + verts(r-1,c)\x + verts(r,c+1)\x + verts(r,c-1)\x - (verts(r,c)\x*4)
End Function

Function DiplacementY#(r%, c%)
	Return verts(r+1,c)\y + verts(r-1,c)\y + verts(r,c+1)\y + verts(r,c-1)\y - (verts(r,c)\y*4)
End Function

Function DiplacementZ#(r%, c%)
	Return verts(r+1,c)\z + verts(r-1,c)\z + verts(r,c+1)\z + verts(r,c-1)\z - (verts(r,c)\z*4)
End Function


Function DiplacementXD#(r%, c%)
	Return verts(r+1,c)\xd + verts(r-1,c)\xd + verts(r,c+1)\xd + verts(r,c-1)\xd - (verts(r,c)\xd*4)
End Function

Function DiplacementYD#(r%, c%)
	Return verts(r+1,c)\yd + verts(r-1,c)\yd + verts(r,c+1)\yd + verts(r,c-1)\yd - (verts(r,c)\yd*4)
End Function

Function DiplacementZD#(r%, c%)
	Return verts(r+1,c)\zd + verts(r-1,c)\zd + verts(r,c+1)\zd + verts(r,c-1)\zd - (verts(r,c)\zd*4)
End Function

-->

Latest Comments

Posted : Sunday, 12 September 2010, 22:48

Jayenkai

ooooh, bouncy!