[seemingly] Random MAV?/Forum (SoCoder)

Forum Home

Blitz

[seemingly] Random MAV?

User

Message

Posted : Thursday, 31 July 2008, 12:41 | Permalink | Mark Here

spinal

[backstory]
Jay's B&W entry a couple of weaks ago got me thinking about that mouse-string code i posted a while ago, so i started tweaking it a bit. Upon Jay's suggestion, i have added actual 'body' segments instead of a simple line, creating a sort of caterpillar. Anyhow, i had a quick attempt at rotating the images (im planning on adding legs) but i keep randomly getting a MAV on the RotateImage line. Can anyone have a go at explaining the problem to me, it seems totally random, just leave the thing sitting in the middle of the screen for a while and 'ding!' MAV!.

; Mouse string, spinal.

Graphics 640,480,0,2
Global tail_len = 160 ; pixel length between the nodes (10 * what we need)
Global tail_nodes = 15 ; How many sections the tail is
Dim nodes_x(tail_nodes) ; X position of each node
Dim nodes_y(tail_nodes) ; Y position

For x=1 To tail_nodes
	nodes_x(x) = MouseX()*10
	nodes_y(x) = MouseY()*10
Next

HidePointer

Global body_part = CreateImage(16,16)
SetBuffer ImageBuffer(body_part)
Color 0,255,0
Oval(0,0,16,16,1)
Color 255,0,0
Oval(1,1,14,14,1)
Color 0,0,0
Line 0,7,15,7
Line 0,8,15,8

SetBuffer BackBuffer()
Repeat
 Cls
 move_tail()
 Flip 1
Until KeyHit(1)
End



Function move_tail()
 nodes_x(0) = MouseX()*10
 nodes_y(0) = MouseY()*10

 For x=1 To tail_nodes
  rotation = ATan2(nodes_y(x)-nodes_y(x-1),nodes_x(x)-nodes_x(x-1))
  pos_x = nodes_x(x-1) + tail_len * Cos(rotation)
  pos_y = nodes_y(x-1) + tail_len * Sin(rotation)
  nodes_x(x) = pos_x
  nodes_y(x) = pos_y

  x1 = nodes_x(x-1)/10
  y1 = nodes_y(x-1)/10
  x2 = nodes_x(x)/10
  y2 = nodes_y(x)/10

	gfxTemp=CopyImage(body_part) 
	MidHandle gfxTemp 
	RotateImage gfxTemp,rotation
	DrawImage gfxTemp,x1,y1
 Next
End Function

-->

|edit| I cant spell and im not allowed to change the title |edit|

-----

3DS - 1762-2660-3218

Posted : Thursday, 31 July 2008, 13:54 | Permalink | Mark Here

mindstorm8191

You should try outputting the values you're feeding into the RotateImage command, before you execute it, plus the size of the image. You can send it either to file or debuglog. Then the last value will be what caused the error, or proof that there is something wrong with the command. ----- Vesuvius web game

Posted : Thursday, 31 July 2008, 13:57 | Permalink | Mark Here

Jayenkai

WW Entries : 103

The line "gfxTemp=CopyImage(body_part)" creates a copy of the image.. The line "" doesn't get rid of it again.. Just keeps copying and copying, and using more and more memory! "FreeImage gfxTemp" at the bottom of the clump would free things up. But, a better way to do it would be to pre-rotate (say) 64 rotations, and just use those instead of constantly re-rotating them.. -----

Posted : Thursday, 31 July 2008, 14:20 | Permalink | Mark Here

Eikon

WW Entries : 7

Example of pre loading rotations: eiksoft.com/eik/articles/arrow.txt

Posted : Thursday, 31 July 2008, 14:44 | Permalink | Mark Here

spinal

thanks guys, it works fin using pre-rotated segments.

; Mouse string, spinal.

Graphics 640,480,0,2
Global tail_len = 160 ; pixel length between the nodes (10 * what we need)
Global tail_nodes = 15 ; How many sections the tail is
Dim nodes_x(tail_nodes) ; X position of each node
Dim nodes_y(tail_nodes) ; Y position

For x=1 To tail_nodes
	nodes_x(x) = MouseX()*10
	nodes_y(x) = MouseY()*10
Next

HidePointer

Global body_part = CreateImage(16,16)
SetBuffer ImageBuffer(body_part)
Color 0,255,0
Oval(0,0,16,16,1)
Color 255,0,0
Oval(1,1,14,14,1)
Color 0,0,0
Line 0,7,15,7
Line 0,8,15,8
TFormFilter 1
Dim img(35) 
 For n=0 To 35
 img(n)=CopyImage(body_part)
 RotateImage img(n),n*10 
 MidHandle img(n)
Next


SetBuffer BackBuffer()
Repeat
 Cls
 move_tail()
 Flip 1
Until KeyHit(1)
End



Function move_tail()
 nodes_x(0) = MouseX()*10
 nodes_y(0) = MouseY()*10

 For x=1 To tail_nodes
  rotation = ATan2(nodes_y(x)-nodes_y(x-1),nodes_x(x)-nodes_x(x-1))
  pos_x = nodes_x(x-1) + tail_len * Cos(rotation)
  pos_y = nodes_y(x-1) + tail_len * Sin(rotation)
  nodes_x(x) = pos_x
  nodes_y(x) = pos_y

  x1 = nodes_x(x-1)/10
  y1 = nodes_y(x-1)/10
  x2 = nodes_x(x)/10
  y2 = nodes_y(x)/10

	rot=rotation/10
	If rot>36 Then rot=rot-36
	If rot<0 Then rot=rot+36
	DrawImage img(rot),x1,y1
 Next
End Function

-->

-----

3DS - 1762-2660-3218

Posted : Thursday, 31 July 2008, 16:09 | Permalink | Mark Here

steve_ancell

Spinal, both of your programs on this thread seem to be working OK on my computer. BTW... That looks fun, what are you making Bud ?.

Posted : Thursday, 31 July 2008, 16:14 | Permalink | Mark Here

spinal

Porbably some sort of snake type game, might end up being nothing, like a lot of my ideas. ----- 3DS - 1762-2660-3218

Posted : Friday, 01 August 2008, 00:14 | Permalink | Mark Here

shroom_monk

WW Entries : 8

"steve_ancell" Spinal, both of your programs on this thread seem to be working OK on my computer. Well, given what Jay said, maybe your computer has enough memory not to run out of space... or you just didn't run it for long enough to run out of memory... ----- A mushroom a day keeps the doctor away... Keep It Simple, Shroom!

Posted : Friday, 01 August 2008, 07:01 | Permalink | Mark Here

steve_ancell

Hmmm, good point. Well spotted Shroom . I had it running for about 2 minutes, and I have 512 MB RAM. I take it that 2 minutes is not long enough.

Posted : Thursday, 05 January 2012, 10:21 | Permalink | Mark Here

spinal

Mildly related to the above... File -- why does this jitter so much? ----- 3DS - 1762-2660-3218

Posted : Thursday, 05 January 2012, 13:27 | Permalink | Mark Here

Afr0

WW Entries : 3

Completely offtopic, but... this is why I'm glad I'm doing a large project right now.
Obviously I've attempted large projects in the past, but the neat thing about the project I'm doing now is that it already comes with tons of data to work with, so I don't have to make that myself or define the format of it.
And since there's sooo much data, and so many formats, there's always something to do, meaning that if I get tired of doing something I can do something else and still work on the project!
For instance, a little over a week ago I had managed to get 3D-rendering working within the client, but somehow it borked the CAS screen so that now nothing can be selected whilst a head is rendering. After spending a day looking through the Lua-scripts and fixing some unrelated bugs in the process, I got tired of bug-hunting and decided it was time to start writing the patch-client.
I spent a couple of days figuring out how to skin a .NET application without using WPF (... XAML >_<), and yesterday I tried loading the animation format. It didn't work out too well, so I scrapped my code and wrote code for loading HAGs (HAndGroup) instead. Now hands and heads can be rendered inside TSO MeshViewer. As I write this I'm in the process of extending TSO MeshViewer's interface so that multiple appearances that are linked to by HAGs and POs (Purchasable Objects) can be viewed when a file is selected.
</offtopic>

Edit: And yesterday I couldn't sleep, so I laid in my bed going through the code given to me by a developer that shall remain nameless, figuring out which functions needed to be ported in order to display bodymeshes.

-----
Afr0 Games

Project Dollhouse on Github - Please fork!

Posted : Thursday, 05 January 2012, 14:57 | Permalink | Mark Here

Jayenkai

WW Entries : 103

sigh I really need to get the upstairs PC working again.. I'll have a look at it in the morning, Spinal. -----

Posted : Friday, 06 January 2012, 01:55 | Permalink | Mark Here

spinal

Forget the jittering, reuploaded... Title using a map now. However my scroll speed is all wrong, I'm a little out of practice, but from what I can tell, it should be right ----- 3DS - 1762-2660-3218