Write : Main Menu/Forum (SoCoder)

Forum Home

Mini Challenges

Write : Main Menu

User

Message

Posted : Tuesday, 22 September 2009, 01:24 | Permalink | Mark Here

Jayenkai

WW Entries : 103

Our new mini-challenge topic has been renamed from Make to Write for a couple of reasons.
1. Fits the "Ye-Olde Basic Commands" list in the newsletter.
2. Make = Make.. I've been reading Make a lot this week, since I reminded myself about it, last week, and feel a bit "Lily Allen" like, having nicked their name!
So, this is now "Write"!

Now, after that nice long intro, a single sentence challenge.

Write the nicest swooshiest main menu you can using only internal commands.

-----

Posted : Tuesday, 22 September 2009, 02:17 | Permalink | Mark Here

Afr0

WW Entries : 3

using only internal commands. You can't say that anymore. Thankfully, everyone's now using C++, C, C# or Java. You and Phoenix are the only ones still using Blitz. And Mog (?) Edit: And Noel ----- Afr0 Games Project Dollhouse on Github - Please fork!

Posted : Tuesday, 22 September 2009, 02:54 | Permalink | Mark Here

Jayenkai

WW Entries : 103

Try reading better. That doesn't say "BLITZ!" anywhere. -----

Posted : Tuesday, 22 September 2009, 03:32 | Permalink | Mark Here

Afr0

WW Entries : 3

What do you mean by 'internal commands' then? o_O ----- Afr0 Games Project Dollhouse on Github - Please fork!

Posted : Tuesday, 22 September 2009, 03:54 | Permalink | Mark Here

JL235

WW Entries : 7

I don't get what he means by internal commands either. But I did notice this is not aimed at any language in particular. ----- PlayMyCode.com - build and play in your browser, Blog, Twitter.

Posted : Tuesday, 22 September 2009, 03:56 | Permalink | Mark Here

Afr0

WW Entries : 3

I automatically thought he meant the internal Blitz commandset. ----- Afr0 Games Project Dollhouse on Github - Please fork!

Posted : Tuesday, 22 September 2009, 04:12 | Permalink | Mark Here

Jayenkai

WW Entries : 103

Print text and draw boxes, draw circles and lines. Use things that within your language you'd find. If you need a package for painting to do it, You haven't quite managed to keep in the spirit. -----

Posted : Tuesday, 22 September 2009, 08:55 | Permalink | Mark Here

Jayenkai

WW Entries : 103

Graphics 800,600,32,2
SetBuffer BackBuffer()

Global options=0
Type tion
	Field ID
	Field name$
	Field SubOf
	
	Field Status
End Type

SetFont LoadFont("Arial",24,1)

sub=Add("Arcade")
		Add("Start",sub)
		sub2=Add("Arcade Options",sub)
				Add("Something",sub2)
				Add("Something Else",sub2)
				Add("Back",sub2,sub)
		Add("Back",sub,0)

sub=Add("Classic")
		add("Start",sub)
		sub2=add("Classic Options",sub)
				Add("Something",sub2)
				Add("Something Else",sub2)
				Add("Back",sub2,sub)
		Add("Back",sub,0)
		
sub=Add("Options")
		add("Music On|Music Off",sub)
		add("Switch to Fullscreen|Switch to Windowed",sub)
		sub2=add("Redefine Keys",sub)
				add("Left : ",sub2)
				add("Right : ",sub2)
				add("Up : ",sub2)
				add("Down : ",sub2)
				Add("Back",sub2,sub)
		Add("Back",sub,0)

InMenu=0
ToMenu=0
MenuSwoosh=0
Repeat
Cls

MH1=MouseHit(1)

If MenuSwoosh<30 Then MenuSwoosh=MenuSwoosh+2
If MenuSwoosh>30 Then MenuSwoosh=MenuSwoosh+2:If MenuSwoosh=>60 Then MenuSwoosh=0:InMenu=ToMenu

y=1
For op.tion=Each tion
	If op\SubOf=InMenu
		Color 180,80,80

		DrawX=900-Sin(MenuSwoosh*3)*700
		DrawY=(Cos(MenuSwoosh*3)*(Sin(op\ID*4)*120))+(y*40)
		DrawW=Sin(MenuSwoosh*3)*400
		DrawH=30

		If mousein(DrawX,DrawY,DrawW,DrawH) 
			Color 200,150,80
			If MH1 And Instr(op\name$,"|")>0 And splittext$(op\name$,"|",op\status+2)<>"-+-" Then MH1=0:op\status=op\status+1
			If MH1 And Instr(op\name$,"|")>0 And splittext$(op\name$,"|",op\status+2)="-+-" Then MH1=0:op\status=0

			If MH1 Then tomenu=op\ID:MenuSwoosh=31
		EndIf
		showText$=op\name$
		If Instr(op\name$,"|")>0 Then showtext$=splittext$(op\name$,"|",op\status+1)

		Rect DrawX,DrawY,DrawW,DrawH,1
		Color ColorRed()+40,ColorGreen()+40,ColorBlue()+40
		Oval DrawX,DrawY,DrawW,DrawH,1

		
		If menuswoosh=30 Then Color 0,0,0:Text DrawX+(DrawW/2),Drawy+(DrawH/2),showtext$,1,1

		y=y+1
	EndIf
Next

If y=1 And menuswoosh=30 Then menuswoosh=31:tomenu=0



Flip
Until KeyDown(1)





Function SplitText$(in$,Split$,e,alsospace=0)
	;Splits text...
	Local out$=""
	Local start=1
	Local nomore=0
	Local shift
	Local size

	in$=Trim(in$)
	e=e-1
	
	For shift=1 To e
		If Instr(in$,Split$,start)+1<=nstart Then nomore=1
		If Instr(in$,Split$,start)+1>nstart Then nstart=Instr(in$,Split$,start)+1
		If AlsoSpace=1 Then If Instr(in$," ",start)+1<nstart And Instr(in$," ",start)>0 Then nstart=Instr(in$," ",start)+1
		start=nstart
	Next
	size=(Instr(in$,Split$,start))-start
	If AlsoSpace=1 Then If (Instr(in$," ",start))-start<size And Instr(in$," ",start)>0 Then size=(Instr(in$," ",start))-start
	

	out$=Mid$(in$,start,size)
	If nomore=1 Then out$="-+-"
	Return out$
End Function

Function mousein(x,y,w,h)
	Return MouseX()=>x And MouseY()=>y And MouseX()<=x+w And MouseY()<=y+h
End Function

Function Add(name$,SubOf=0,ForceID=-1)
	options=options+1
	
	op.tion=New tion
	op\ID=options:If forceID>-1 Then op\ID=ForceID
	op\name$=name$
	op\SubOf=SubOf
	
	op\Status=0
Return Options
End Function

-->

-----

Posted : Tuesday, 22 September 2009, 09:53 | Permalink | Mark Here

Eikon

WW Entries : 7

Graphics 640, 480, 16, 2
SetBuffer BackBuffer()
SeedRnd MilliSecs()

Dim menuR(9), menuA#(9), menuS$(9), menuW#(9)

For i = 0 To 8
	menuR(i) = Rand(150, 200)
	menuA(i) = i * 40
	menuS$(i) = "Menu Option " + Str(i + 1)
Next

Local tmpO#

Local Font = LoadFont("Verdana", 18, 0, 0, 0)
SetFont Font

While Not KeyDown(1)

If KeyDown(203) Then 
	If tmpO > -2 Then tmpO = tmpO - .02
ElseIf KeyDown(205) Then
	If tmpO < 2 Then tmpO = tmpO + .02
Else
	If tmpO > 0 Then 
		tmpO = tmpO - .01
	Else
		tmpO = tmpO + .01
	EndIf
EndIf

For i = 0 To 9
	tmpX = Cos(menuA(i)) * menuR(i) + 320
	tmpY = -Sin(menuA(i)) * menuR(i) + 240
	
	Color 255, 255, 255
	Line 320, 240, tmpX, tmpY - 10
	
	If menuA(i) >= 260 And menuA(i) <= 280 Then 
		Color 0, 255, 0
	Else 
		Color 255, 255, 0
	EndIf

	Text tmpX - (StringWidth(menuS$(i)) / 2), tmpY - 12, menuS$(i)
	
	menuA(i) = menuA(i) + tmpO
	If menuA(i) > 360 Then menuA(i) = 0
	If menuA(i) < 0 Then menuA(i) = 360
	
Next

Color 255, 255, 255
Oval 320 - 10, 240 - 10, 20, 20, 1
Color 0, 0, 0
Oval 320 - 9, 240 - 9, 18, 18, 1

Color 0, 255, 0
Oval 200, 360, 250, 100, 0

Color 255, 255, 255
Text 1, 1, "Left / Right Arrow Keys - " + Left(Str(tmpO), 4)

Flip: Cls
Wend: End

-->

Posted : Wednesday, 23 September 2009, 01:37 | Permalink | Mark Here

Jayenkai

Weeeee! That'd look cool with sub-obtions

Posted : Wednesday, 23 September 2009, 03:14 | Permalink | Mark Here

CodersRule

Ooh can we make a whole bunch of Data statements and save an image in it? XD