Wednesday Workshop

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|508|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-

Eat

by Phoenix for Workshop #115

Eat the same coloured circles.

Mouse

Graphics( 400, 400, 16, 2 )
SetBuffer( BackBuffer() )
SeedRnd( MilliSecs() )

Type Thingy
	Field x#, y#, col
	Field ang
End Type

Type Particle
	Field x#, y#
	Field r, g, b
	Field ang#, spd#
End Type

gameMode$ = "MENU"
px# = 200
py# = 200
Global spin = 1
score = 0
best = 0

SetFont( LoadFont( "ARIAL2", 16 ) )

timer = CreateTimer( 60 )

While( Not KeyHit( 1 ) )
	WaitTimer( timer )
	mx = MouseX()
	my = MouseY()
	mang = -ATan2( py - my, px - mx ) - 90
	ang = ang + (spin*3) Mod 360
	
	Select( gameMode )
		Case "GAME"		
			If( swap < MilliSecs() )
				spin=-spin
				swap = MilliSecs() + 10000
			EndIf
			
			score = score + 1
			
			If( Rand( 3 ) = 1 )
				t.Thingy = New Thingy
				t\x = 500 * Sin( Rand( 360 ) ) * 4
				t\y = 500 * Cos( Rand( 360 ) ) * 4
				t\col = -1 + (Rand( 0, 1 )*2)
			EndIf
			
			For t.Thingy = Each Thingy
				t\ang = -ATan2( t\y - (py+Rand( 15 )), t\x - (px+Rand( 15 )) ) - 90
				
				t\x = t\x + Sin( t\ang )
				t\y = t\y + Cos( t\ang )
				
				If( t\col = -1 ) Then Color( 0, 0, $00FF00 )
				If( t\col = 1 ) Then Color( 0, 0, $FF0000 )
				
				If( RectsOverlap( t\x, t\y, 10, 10, px-20, py-20, 40, 40 ) )
					If( t\col = spin )
						For i = 0 To 360
							p.Particle = New Particle
							p\x = t\x
							p\y = t\y
							p\r = Rand( 255 )
							p\g = Rand( 255 )
							p\b = Rand( 255 )
							p\spd# = Rand( 5, 15 )
							p\ang = i+135
						Next
						
						Delete t
						score = score + 500
						Exit
					EndIf
					
					Cls
					Color( 0, 0, $FF0000 )
					Text( 200, 200, "YOU LOSE!   SCORE: " + score, 1, 1 )
					If( score > best ) Then best = score
					Flip
					Delay 3000
					FlushKeys
					gameMode = "MENU"
				EndIf
				
				Oval( t\x, t\y, 10, 10 )
			Next
			
			For p.Particle = Each Particle
				p\x = p\x + Sin( p\ang ) * p\spd
				p\y = p\y + Cos( p\ang ) * p\spd
				p\y = p\y + 3
				p\ang = p\ang + (Sgn(p\ang-185)/4)
				
				Color( p\r, p\g, p\b )
				Rect( p\x, p\y, 2, 2 )
			Next
						
			scoreText$ = "SCORE: " + Replace( RSet( score, 10 ), " ", "0" )
	
			Color( 0, 0, $FFFFFF )
			Text 400-StringWidth( scoreText ), 400-16, scoreText
			
			Color( 0, 0, $0000FF )
			Rect( 1, 1, (swap - MilliSecs())/25, 15 )
		Case "MENU"
			If( RectsOverlap( px-20, py-20, 40, 40, 200, 160, StringWidth( "PLAY" ), 16 ) )
				Color( 0, 0, $FFFF00 )
				
				If( MouseDown( 1 ) )
					gameMode = "GAME"
					px# = 200
					py# = 200
					spin = 1
					score = 0
					swap = MilliSecs() + 10000
					Delete Each Thingy
					Delete Each Particle
				EndIf
			Else
				Color( 0, 0, $FFFFFF )
			EndIf
			Text( 200 - StringWidth( "PLAY" ) / 2, 160, "PLAY" )
			
			
			If( RectsOverlap( px-20, py-20, 40, 40, 200, 240, StringWidth( "EXIT" ), 16 ) )
				Color( 0, 0, $FFFF00 )
				
				If( MouseDown( 1 ) ) Then End
			Else
				Color( 0, 0, $FFFFFF )
			EndIf
			Text( 200 - StringWidth( "EXIT" ) / 2, 240, "EXIT" )
			
			scoreText$ = "BEST SCORE: " + Replace( RSet( best, 10 ), " ", "0" )
	
			Color( 0, 0, $FFFFFF )
			Text 400-StringWidth( scoreText ), 400-16, scoreText
	End Select
	
	px = px + Sin( mang ) * 3
	py = py + Cos( mang ) * 3
	DrawPlayer( px, py, ang )
		
	Flip
	Cls
Wend
End

Function DrawPlayer( x, y, ang# )
	corners = 5
	stp = 360 / corners
	radius = 20
	
	If( spin > 0 ) Then Color( 0, 0, $FF0000 )
	If( spin < 0 ) Then Color( 0, 0, $00FF00 )
	
	For i = 0 To 5
		Line( radius * Sin( i * stp + ang ) + x, radius * Cos( i * stp + ang ) + y, radius * -Sin( i * stp + ang ) + x, radius * -Cos( i * stp + ang ) + y )
	Next
End Function

Shoot The Ship

by Phoenix for Workshop #121

Shoot the Ship, but beware the delays

Spacebar.. Then wait!

Graphics(640, 480, 32, 2)
SetBuffer(BackBuffer())
SeedRnd(MilliSecs())

shipPos# = 640
bulletPos = 470
fired = False
del# = 2500
waittmr = -1
bulSpd# = 2
score = 0
high = 0
level = 1

timer = CreateTimer(60)

While(Not KeyHit(1))
	WaitTimer(timer)
	
	shipPos = shipPos - 1
	
	If(KeyHit(57)) Then waittmr = del+MilliSecs()
	
	If(waittmr > 0)
		If(waittmr =< MilliSecs())
			fired=True
		EndIf
	EndIf
	
	If(fired) Then bulletPos = bulletPos - bulSpd
	
	If(RectsOverlap(118, bulletPos, 4, 4, shipPos, 20, 80, 10))
		score = score + Rand(level*1000, level*10000)
		level = level + 1
		bulSpd = Rand(1, 5)
		del = Rand(25, 50)*100
		fired = False
		shipPos = 640
		bulletPos = 470
		waittmr = -1
		If(score>high) Then high=score
	Else If(bulletPos < 0 Or shipPos < -80)
		shipPos# = 640
		bulletPos = 470
		fired = False
		del# = 2500
		waittmr = -1
		bulSpd# = 2
		score = 0
		level = 1
		If(score>high) Then high=score
	EndIf
	
	Rect(118, bulletPos, 4, 4)
	
	Color(255,128,0)
	Rect(shipPos, 20, 80, 10)
	Color(255, 200, 100)
	Rect(shipPos, 20, 80, 10, 0)
	
	Color(0,128,255)
	Rect(110, 470, 20, 10)
	Line(120, 470, 120, 460)
	
	Color(255,255,255)
	Text(0,0,"Delay: "+del/1000+" seconds")
	Text(0,12,"Bullet speed: "+bulSpd)
	Text(0,24,"Score: "+score)
	Text(0,36,"Highest score: " +high)
	Flip
	Cls
Wend
End

Make It Blue

by Phoenix for Workshop #125

Turn the light blue squares Dark, by guiding the Orange square around. The Green squares stop your movement.

Cursors

; ---------------------------------
;
; Made by Phoenix, 18/11 -07, 13:51-15:29
; 1 hour and 38 minutes
;
; ---------------------------------
;
; Use the arrow keys to move the orange dot.
; Green tiles prevents sliding,
; however there are only a few on every level.
; As you move, the board will change color.
; Your goal is to fill the entire level with dark blue,
; and if you think you're lost just press space to reset.
; Sometimes when you have beaten a level, nothing happens.
; If that happens, don't call 911 - relax instead.
; Just push one of the arrow keys and pray to god that it will work (if you're religious)
;
; Beat all six levels to view the ultra-cool ending screen!
; But whatever you do, don't cheat! All levels are possible.
;
; ---------------------------------

Graphics 256,256,0,2
SetBuffer(BackBuffer())
SeedRnd(MilliSecs())

Global pX,pY
Dim map(8,8)

timer = CreateTimer(50)

Global stopped = 0
Global move = 0
Global xmod = 0
Global ymod = 0
Global level = 0 ; One less than the actual level, since we increase it in NextLevel()

NextLevel()

While(Not KeyHit(1))
	WaitTimer(timer)
	done = True
	For x = 0 To 7
		For y = 0 To 7
			Select(map(x,y))
				Case 0 Color 60,120,200 : done = False
				Case 1 Color 60,60,60
				Case 2 Color 40,100,180
				Case 3 Color 60,200,120
			End Select
			
			Rect x*32,y*32,32,32
		Next
	Next
	
	If(done)
		Color(255,255,255)
		Cls
		Text 128,128,"Well done! You beat level "+level,1,1
		Flip
		Delay 2000
		NextLevel()
	EndIf
	
	If(KeyHit(57)) Then level=level-1 NextLevel()
	
	If(map(pX,pY)=3 And stopped=0) Then move=0 : stopped = 1
	
	If(KeyHit(200) And move=0) Then move = 1
	If(KeyHit(205) And move=0) Then move = 2
	If(KeyHit(208) And move=0) Then move = 3
	If(KeyHit(203) And move=0) Then move = 4

	Select(move)
		Case 1
			If(map(pX,pY-1)=1)
				move = 0
			Else
				ymod = ymod - 8
				If(Abs(ymod)=32)
					If(map(pX,pY)=2 Or map(pX,pY) = 0) Then map(pX,pY) = Abs(map(pX,pY)-2)
					pY=pY-1
					ymod=0
					stopped=0
				EndIf	
			EndIf
		Case 2
			If(map(pX+1,pY)=1)
				move = 0
			Else
				xmod = xmod + 8
				If(Abs(xmod)=32)
					If(map(pX,pY)=2 Or map(pX,pY) = 0) Then map(pX,pY) = Abs(map(pX,pY)-2)
					pX=pX+1
					xmod=0
					stopped=0
				EndIf
			EndIf
		Case 3
			If(map(pX,pY+1)=1)
				move = 0
			Else
				ymod = ymod + 8
				If(Abs(ymod)=32)
					If(map(pX,pY)=2 Or map(pX,pY) = 0) Then map(pX,pY) = Abs(map(pX,pY)-2)
					pY=pY+1
					ymod=0
					stopped=0
				EndIf
			EndIf
		Case 4
			If(map(pX-1,pY)=1)
				move = 0
			Else
				xmod = xmod - 8
				If(Abs(xmod)=32)
					If(map(pX,pY)=2 Or map(pX,pY) = 0) Then map(pX,pY) = Abs(map(pX,pY)-2)
					pX=pX-1
					xmod=0
					stopped=0
				EndIf
			EndIf
	End Select
	
	Color 200,120,60
	Rect pX*32+xmod, pY*32+ymod,32,32
	Flip
	Cls
Wend
End

Function NextLevel()
	level = level + 1
	xmod = 0
	ymod = 0
	stopped = 0
	move = 0
	
	Select(level)
		Case 1 Restore level1
		Case 2 Restore level2
		Case 3 Restore level3
		Case 4 Restore level4
		Case 5 Restore level5
		Case 6 Restore level6
		Case 7
			Color 255,255,255
			SetFont(LoadFont("Arial",18))
			While(Not KeyHit(1))
				a=a+1
				If(Rand(10)=1)
					For i = 0 To 360 Step 10
						p.particle = New particle
						p\x = Rand(64,192)
						p\y = Rand(64,192)
						p\c = Rand($FFFFFF)
						p\a = i
					Next
				EndIf
				
				For p.particle = Each particle
					p\x=p\x+Sin(p\a)*5
					p\y=p\y+Cos(p\a)*5
					WritePixel p\x, p\y, p\c
					
					If(p\x>256 Or p\x<0 Or p\y>256 Or p\y<0) Then Delete p
				Next
				
				Text Sin(a)*25+128,128,"You won! Congratulations!",1,1
				Flip
				Cls
			Wend
			End
	End Select
	
	Read pX
	Read pY

	For y = 0 To 7
		For x = 0 To 7
			Read map(x,y)
		Next
	Next
End Function

Type particle
	Field x,y,c,a
End Type

.level1
Data 2,2
Data 1,1,1,1,1,1,1,1
Data 1,1,1,1,1,1,1,1
Data 1,1,0,0,0,0,1,1
Data 1,1,1,1,1,0,1,1
Data 1,1,1,0,0,3,1,1
Data 1,1,0,0,0,0,1,1
Data 1,1,1,1,1,1,1,1
Data 1,1,1,1,1,1,1,1

.level2
Data 2,5
Data 1,1,1,1,1,1,1,1
Data 1,1,1,1,1,1,1,1
Data 1,1,0,0,1,0,1,1
Data 1,1,3,0,0,0,1,1
Data 1,1,0,1,0,3,1,1
Data 1,1,0,1,0,0,1,1
Data 1,1,1,1,1,1,1,1
Data 1,1,1,1,1,1,1,1

.level3
Data 5,3
Data 1,1,1,1,1,1,1,1
Data 1,1,0,0,0,0,1,1
Data 1,1,0,1,1,0,0,1
Data 1,1,0,1,0,3,0,1
Data 1,0,0,1,0,0,1,1
Data 1,0,0,0,0,0,1,1
Data 1,1,1,1,0,0,1,1
Data 1,1,1,1,1,1,1,1

.level4
Data 3,3
Data 1,1,1,1,1,1,1,1
Data 1,1,1,1,1,1,1,1
Data 1,1,1,1,1,1,1,1
Data 1,2,2,2,1,1,1,1
Data 1,2,1,2,1,1,1,1
Data 1,2,1,3,2,2,0,1
Data 1,2,2,2,2,2,2,1
Data 1,1,1,1,1,1,1,1

.level5
Data 6,4
Data 1,1,1,1,1,1,1,1
Data 1,1,1,1,1,1,1,1
Data 1,1,1,0,0,0,0,1
Data 1,1,0,0,0,1,0,1
Data 1,1,0,0,3,0,0,1
Data 1,1,0,1,0,1,1,1
Data 1,1,0,0,0,1,1,1
Data 1,1,1,1,1,1,1,1

.level6
Data 4,2
Data 1,1,1,1,1,1,1,1
Data 1,1,1,1,1,1,1,1
Data 1,1,0,0,0,1,1,1
Data 1,1,0,1,3,0,0,1
Data 1,2,2,0,3,1,0,1
Data 1,2,1,1,0,1,0,1
Data 1,2,2,2,0,0,0,1
Data 1,1,1,1,1,1,1,1

Joe

by Phoenix for Workshop #160

Help Joe find his missing XBox

Click to download this entry

Pacman

by Phoenix for Workshop #200

Avoid the ghosts

Cursor Keys

Click to download this entry