Wednesday Workshop

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|507|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-

Green Snake

by Jayenkai for Workshop #069

Guide the green, grab the blue, avoid the red.

Mouse

; Started 23:30
; Completed 00:20

SW=640
SH=480
Graphics SW,SH,32,2
SetBuffer BackBuffer()

SSize=4
Wid=(SW/SSize)+1
Hig=(SH/SSize)+1
Dim map(Wid,Hig)

Global MX,MY

Type git
Field x,y,gx,gy
End Type

hiscore=0

.TitleScreen
Repeat
Cls

Color 180,180,255:Text sw/2,sh/2-40,"Get the Blue Squares",1,1
Color 255,180,180:Text sw/2,sh/2,"Avoid the Red Squares",1,1
Color 180,255,180:Text sw/2,sh/2+40,"Today's Best Score : "+hiscore,1,1

If MouseDown(1) Then Gosub StartRound:If score>hiscore Then hiscore=score

Flip
Until KeyDown(1)

End




.StartRound
endofgame=0
For x=0 To Wid
For y=0 To Hig
map(x,y)=0
Next
Next

MX=MouseX()/8
MY=MouseY()/8
MX=(MX*8)+4
MY=(MY*8)+4

For a.git=Each git:Delete a.git:Next
lev=25
score=0
mscore=5
Repeat
Cls

Color 255,255,255
Text sw/2,10,Score

For x=0 To Wid
For y=0 To Hig

	If map(x,y)<0
		map(x,y)=map(x,y)+1
		Color 0,0,255:If map(x,y)=0 Then Color 0,0,0
		Rect x*ssize,y*ssize,ssize,ssize,1
	EndIf
	If map(x,y)>0
		map(x,y)=map(x,y)-1
		Color map(x,y)*5,map(x,y)*15,map(x,y)*5
		Rect x*ssize,y*ssize,ssize,ssize,1
	EndIf
	If mousein(x*ssize,y*ssize,ssize,ssize) 
		If map(x,y)<0 Then Score=Score+1
		map(x,y)=15
	EndIf

Next
Next


For a.git=Each git
kill=0
a\x=a\x+a\gx
a\y=a\y+a\gy
If mousein(a\x,a\y,16,16) Then endofgame=1
Color 255,0,0
Rect a\x,a\y,16,16,1
If a\gx<0 And a\x<-20 Then kill=1
If a\gx>0 And a\x>sw+20 Then kill=1
If a\gy<0 And a\y<-20 Then kill=1
If a\gy>0 And a\y>sh+20 Then kill=1
If kill=1 Then Delete a.git
Next

ts=4
If score>mscore And lev>4 Then mscore=mscore+5:lev=lev-4

If Rand(1,10)=1 Then map(Rand(0,wid),Rand(0,hig))=Rand(-100,-150)
If Rand(1,lev)=1
a.git=New git
side=Rand(1,4)
If side=1
	a\x=Rand(0,sw):a\y=-20
	a\gx=Rand(-ts,ts):a\gy=Rand(1,ts)
EndIf

If side=2
	a\x=-20:a\y=Rand(0,sh)
	a\gx=Rand(1,ts):a\gy=Rand(-ts,ts)
EndIf

If side=3
	a\x=Rand(0,sw):a\y=sh+20
	a\gx=Rand(-ts,ts):a\gy=Rand(-1,-ts)
EndIf

If side=4
	a\x=sw+20:a\y=Rand(0,sh)
	a\gx=Rand(-1,-ts):a\gy=Rand(-ts,ts)
EndIf

EndIf


MHL=MouseHit(1)
MHR=MouseHit(2)

If MX<MouseX() Then MX=MX+ssize
If MX>MouseX() Then MX=MX-ssize
If MY<MouseY() Then MY=MY+ssize
If MY>MouseY() Then MY=MY-ssize


Flip
If KeyDown(1) Then endofgame=99
Until endofgame<>0

Repeat
Text sw/2,sh/2,"DEAD",1,1
Flip
If KeyDown(1) Then End
Until MouseDown(1)
Repeat
Text sw/2,sh/2,"DEAD",1,1
Flip
Until MouseDown(1)=0
Return


Function Mousein(x,y,w,h)
Return (MX=>x And MX<=x+w And MY=>y And MY<=y+h)
End Function


Function Col(n)
Select n
Case 1
Color 255,0,0
Case 2
Color 255,180,180
Case 3
Color 255,255,0
Case 4
Color 255,255,255
Case 5
Color 0,255,0
Case 6
Color 180,255,180
Case 7
Color 0,0,255
Case 8
Color 180,180,255
Case 9
Color 255,0,255
Case 10
Color 0,0,0
End Select
End Function