Wednesday Workshop

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|541|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-

Line Squiggles

by Jayenkai for Workshop #062

Move the mouse through the cavern.

Mouse

Graphics 800,600,32,2
SetBuffer BackBuffer()
SeedRnd MilliSecs()
HidePointer()

Top#=Rand(0,300)
High#=Rand(100,300)
Topgo#=0
Highgo#=0

Font=LoadFont("Arial",26)
SetFont font

MB#=2
Dim LC#(100,2)

Wall=CreateImage(900,600)
Squiggle=CreateImage(810,600)
Health=800


Highscore=0


SaveScores=0
;Set to 1 if you'd like to save your highscores.
SaveDir$="system/062/"
;But make sure this directory exists..


SaveFile$="highscoreB.dat"
If savescores=1
	If FileType(savedir+savefile)=1
		quicky=ReadFile(savedir+savefile)
		highscore=ReadInt(quicky)
		CloseFile quicky
	EndIf
EndIf


.MainMenu

Repeat
Cls
Color 255,255,255

Text 400,50,"Line Squiggles",1,1
Color 255,0,0
Text 400,300,"Move the mouse through the cavern.",1,1
Color 0,255,0
Text 400,500,"Best Time : "+Millisecstotime(HighScore),1,1

If MouseDown(1) Then Gosub StartRound

Flip
Until KeyDown(1)


Return



.Startround
SetBuffer ImageBuffer(Wall)
Cls
SetBuffer ImageBuffer(Squiggle)
Cls
SetBuffer BackBuffer()

Checkpoint#=5
MB#=2
Start=MilliSecs()
endofgame=0
Health=800
Repeat


SetBuffer ImageBuffer(Wall)
CopyRect MB,0,800,600,0,0

Color 0,0,0
Rect 800-MB,0,MB,600,1

For n=1 To MB
High=High+Highgo
Top=Top+Topgo
If Rand(1,30)=4 Then TopGo=Rnd(-0.4,0.4)
If Rand(1,30)=8 Then HighGo=Rnd(-0.4,0.4)
If High>300 Then High=300:Highgo=-0.4
If High<100 Then High=100:Highgo=0.4
If Top+High>590 Then Top=590-High:Topgo=-0.4
If Top<10 Then Top=10:Topgo=0.4


Color 25,25,25
Line (799-MB)+n,0,(799-MB)+n,Top
Line (799-MB)+n,Top+High,(799-MB)+n,600

Next


SetBuffer ImageBuffer(Squiggle)
CopyRect MB,0,800-MB,600,0,0

Color Rand(75,255),Rand(75,255),Rand(75,255)
Rect 800-MB,0,MB,600,1


For n=1 To MB-1
DP#=(200/MB)
Color n*DP,n*DP,n*DP
Line LC(n,1)-MB+n,LC(N,2),LC#(n+1,1),LC#(n+1,2)

LC#(n,1)=lc#(n+1,1)
LC#(n,2)=lc#(n+1,2)
Next

For n=MB To 100
LC(n,1)=MouseX()
LC(n,2)=MouseY()
Next

SetBuffer BackBuffer()

LockBuffer ImageBuffer(Wall)
ImOn=(ReadPixelFast(MouseX(),MouseY(),ImageBuffer(Wall)) And %011111111)
UnlockBuffer ImageBuffer(Wall)

If ImOn>10 Then Health=Health-((MB/2)+1)

Cls
DrawImage Squiggle,0,0
DrawImage Wall,0,0

Color 255,255,255
Rect 0,0,Health,10

GameTime=MilliSecs()-Start
Text 400,590,Millisecstotime(GameTime),1,1

If (Gametime/1000)>Checkpoint Then MB=MB+1:Checkpoint=Checkpoint+5

If Gametime>Highscore Then Highscore=Gametime

Flip
If Health<=0 Then Endofgame=1
If KeyDown(1) Then Endofgame=99
Until Endofgame<>0

If savescores=1
		quicky=WriteFile(savedir+savefile)
		WriteInt(quicky,Highscore)
		CloseFile quicky
EndIf

Return





Function millisecstotime$(mills,hron=0,minon=1,secon=1,milson=1)
out$=""
millsecs=(mills Mod 1000)/10
mills=(mills/1000)
secs=mills Mod 60
mills=(mills/60)
mins=mills Mod 60
mills=(mills/60)
If hron=1 Then out$=out$+xdigitstring$(mills,2)+":"
If minon=1 Then out$=out$+xdigitstring$(mins,2)+":"
If secon=1 Then out$=out$+xdigitstring$(secs,2)+":"
If milson=1 Then out$=out$+xdigitstring$(millsecs,2)
Return out$
End Function

Function xdigitstring$(integer,digits)
curstring$=Str$(integer)
If Len(curstring$)>digits Then curstring$=Right(curstring$,digits)
If Len(curstring$)<digits
noed=digits-Len(curstring$)
curstring$=String$("0",noed)+Str$(curstring$)
EndIf
Return curstring$
End Function