Simple stack-based interpreter/Code Snippet (SoCoder)

Created 04 September 2010 | Last Edited 04 September 2010)

Simple stack-based interpreter by Tikihead | No Votes
Includes comments and example ''programs''

I wrote this something like a year ago but ran into it today, so I thought I'd post it. Anyways this takes a string of basic commands arranged in postfix and runs it through a lexer and parser/interpreter. This bit of code handles some unary and binary operators, variables, input and output, and if/elseif/else statements.
Obviously it is an extremely slow/limited implementation but with a bit of work and playing around it can easily be made better.

For example...

Add more functions!

Use something other than a space to separate tokens so you can put spaces in string literals

Use the shunting yard algorithm or similar to allow the user to input regular infix algebra

Tokenize the program beforehand to speed things up

Get rid of every string except string literals to speed things up drastically

If you have any questions just ask.

;====================================================================
; Author: 		Tikihead
; Date:			Sept 4, 2010
; Description: 	A simple stack-based postfix interpreter. Do whatever
;				you want with this code, I don't really care.
; Notes:		-Make sure to put a space after each statement
;				-Nested "if" statements don't work
;				-Don't have any two tokens be the same, e.g. a string
;				 literal "bob" and a variable "bob"
;				-You can only compare numbers, not string literals
;====================================================================

SeedRnd MilliSecs()

Global program$		;stack of commands to be run
Global token$		;next token (command) to be taken care of
Global stack$		;stack of data
Global num1%,num2%	;used for getting data off the stack when calling functions

Type Variable
	Field name$
	Field value$
End Type

;--------------------example programs, uncomment only one
;prints "Hello_world!"
program = "Hello_world! print "
;performs this algebra: (((17 + 33) * 2) - 50) / 2
;program = "17 33 + 2 * 50 - 2 / "
;asks for the user's age and prints it back out
;program = "Enter_your_age print ... Wow,_you_are input print print print years_old! print "
;makes a variable, multiplies it by 2, then prints it out
;program = "17 mynum sto mynum 2 * print "
;if statement example
;program = "5 5 + 10 = if Success print else Failure print endif "
;a guessing game. First part gets number and user's guess, second+third part checks user's input, fourth part prints results
;program = "1 10 rand num sto Enter_a_number_1-10 print input guess sto "
;program = program + "guess 1 < if You_entered_an_invalid_guess print end endif "
;program = program + "guess 10 > if You_entered_an_invalid_guess print end endif "
;program = program + "guess num = if You_win! print else You_lose! print endif Number: num print print Guess: guess print print "

Print "Program: "+program
Print "Output
Print "---------------------"

;while there are still tokens left
While Len(program) > 0
	;get the next token
	token = Pop("program")
	;evaluate token, push result (if any) onto stack
	Select token
		Case "sto";variable creation
			If token = "sto" Then StoVar(Pop("stack"),Pop("stack"))
		Case "not","sgn","abs";unary operators
			num1 = Int(Pop("stack"))
			If token = "not" Then Push(Not num1)
			If token = "sgn" Then Push(Sgn(num1))
			If token = "abs" Then Push(Abs(num1))
		Case "+","-","*","/","=","or","and","rand",">","<","<=",">=","=<","=>";binary operators
			num1 = Int(Pop("stack"))
			num2 = Int(Pop("stack"))
			If token = "+" Then Push(num1 + num2)
			If token = "-" Then Push(num1 - num2)
			If token = "*" Then Push(num1 * num2)
			If token = "/" Then Push(num1 / num2)
			If token = "=" Then Push(num1 = num2)
			If token = "or" Then Push(num1 > 0 Or num2 > 0)
			If token = "and" Then Push(num1 > 0 And num2 > 0)
			If token = "rand" Then Push(Rand(num1,num2))
			If token = ">" Then Push(num1 > num2)
			If token = "<" Then Push(num1 < num2)
			If token = "=>" Or token = ">=" Then Push(num1 => num2)
			If token = "=<" Or token = "<=" Then Push(num1 =< num2)
		Case "input","print";input/output functions
			If token = "input" Then Push(Input(">"))
			If token = "print" Then Print Pop("stack")
		Case "if","else","endif";evaluation functions
			If token = "if"
				If Pop("stack") = False
					;if false, skip tokens until "else" or "endif" are hit
					While token <> "else" And token <> "endif"
						token = Pop("program")
					Wend
				EndIf
			ElseIf token = "else"
				;skip tokens until the end of the if statement structure is hit
				While token <> "endif"
					token = Pop("program")
				Wend
			EndIf
		Case "end";misc
			If token = "end" Then Exit
		Default;a value
			Push(GetVar(token))
	End Select
Wend

Print "---------------------"
Print "Done"
Print "Result: "+stack
FlushKeys:WaitKey
End

;Push a value onto the front of the data stack
Function Push(thing$)
	stack = stack + thing + " "
End Function

;Pop a token off either the program or the data stack
Function Pop$(thing$)
	Local toTake%
	Local toReturn$
	If thing = "program"
		toTake = Instr(program," ")
		toReturn = Left(program,toTake-1)
		program = Right(program,Len(program)-toTake)
	ElseIf thing = "stack"
		toTake = Instr(stack," ")
		toReturn = Left(stack,toTake-1)
		stack = Right(stack,Len(stack)-toTake)
	EndIf
	Return toReturn
End Function

;Store a variable or make a new one
Function StoVar(value$,name$)
	For v.Variable = Each Variable
		If v\name = name Then v\value = value:Return
	Next
	v.variable = New Variable
	v\name = name
	v\value = value
	Return
End Function

;Return the value of a variable
Function GetVar$(name$)
	For v.Variable = Each Variable
		If v\name = name Then Return v\value
	Next
	Return name
End Function

-->

There are no comments for this entry.