Wednesday Workshop

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|531|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-
Paddle Ball

by WillK for Workshop #001
Try to beat the computer player.
Cursors
;==========================================================================
;=============================== Paddle Ball ==============================
;=========================== Programmed by WillK ==========================
;================== Coders Workshop Wednesday Workshop #001 ===============
;=============================== 16 June 2005 =============================
;==========================================================================



;==========================================================================
;=============================== Initialise Game Variables ================
;==========================================================================
Graphics 640,480,32,2
SetBuffer BackBuffer()
SeedRnd MilliSecs()
AppTitle "Silly Little Paddle Ball Game"

	;game variables
	Const VICTORY=5
	Const BORDER=40
	Global pspeed#=1
	Global pause=False,quit=False,pausetime
	Global frames,fpstimer,gwidth=GraphicsWidth(),gheight=GraphicsHeight()
	Global fps=60,state$
	

	;declare paddle variables
	Const PFLASH=250
	Global rectw=gwidth/32
	Global recth=(gheight/4)
	Dim pcolor(1,2)
	Dim ptimer(1)

	;declare player variables	
	Global px,py,pscore
	
	;declare computer variables
	Global cx,cy,cscore
	
	;declare ball variables
	Global bw=gwidth/64
	Global bh=bw
	Global bx#,by#,bspeedx#,bspeedy#,lx,ly,btimer,bred,bgreen,bblue

	;load fonts
	Global arial=LoadFont("Arial",36,True)
	Global arialc=LoadFont("Arial",18,True)
	Global arialb=LoadFont("Arial",72,True)


	drawTitle()
	initGame()



;==========================================================================
;=============================== Main Game Loop  ==========================
;==========================================================================
Repeat

	getInput()
	checkCollisions()

	ClsColor 128,0,0
	Cls
		;draw court
		Color 0,64,0
		Rect rectw,BORDER,gwidth-2*rectw,gheight-2*BORDER
		
		;draw paddles
		Color pcolor(1,0),pcolor(1,1),pcolor(1,2)
		Rect cx,cy,rectw,recth,True
		Color pcolor(0,0),pcolor(0,1),pcolor(0,2)
		Rect px,py,rectw,recth,True
		
		;draw ball
		Color 255,255,255
		If pause=0 Or pause=10 Rect bx,by,bw,bh,True
		
		;draw HUD
		drawHUD()

	Flip True

Until quit=True

ClsColor 0,0,0
Cls
updateHUD(7)
drawHUD(2)
Flip
While MilliSecs()<pausetime
Wend


End


;==========================================================================
;=============================== Get User Input ===========================
;==========================================================================
Function getInput()
	
	If KeyDown(1) 
		quit=True
	ElseIf KeyHit(197) Or KeyHit(25)
		If pause=11 
			pause=0
		ElseIf pause=0
			pause=11
		EndIf
	EndIf
	If pause=0	
		If KeyDown(200)
			py=py-pspeed
		ElseIf KeyDown(208)
			py=py+pspeed
		EndIf
		updateBall()
		updateAI()
		updatepaddle()
	ElseIf pause=6
		If KeyDown(21) initGame()
		If KeyDown(49) quit=True
	Else
		If MilliSecs()>pausetime
			If pause=1 Or pause=2 Or pause=3
				updateHUD(10)			
			ElseIf pause=4 Or pause=5 
				updateHUD(6)
			ElseIf pause=11
			
			Else
				pause=0
			EndIf
		EndIf
	EndIf
End Function




;==========================================================================
;=============================== Initialise Game Variables ================
;==========================================================================
Function initGame()
	
	;setup paddles
	For i=0 To 1
		pcolor(i,0)=247
		pcolor(i,1)=235
		pcolor(i,2)=5
	Next
	
	;initialise player
	px=20
	py=(gheight-recth)/2
	pscore=0
	
	;initialise computer
	cx=gwidth-(20+rectw)
	cy=py
	cscore=0

	;setup game
	pspeed#=gheight/64
	
	
	initBall()	
	updateHUD()

End Function


;==========================================================================
;=============================== Update Ball ==============================
;==========================================================================
Function updateBall()
	lx=bx
	bx=bspeedx+bx
	ly=by
	by=bspeedy+by
	
	If by<BORDER	
		bspeedy=-bspeedy
		by=by+bh
	ElseIf by>(gheight-BORDER-bh) 
		bspeedy=-bspeedy
		by=by-bh
	EndIf
	If bx>gwidth
		pscore=pscore+1
			If pscore=VICTORY 
				updateHUD(4)
			Else
				updateHUD(1)
			EndIf
		initBall()
		Return
	ElseIf bx<0
		cscore=cscore+1
			If cscore=VICTORY 
				updateHUD(5)
			Else
				updateHUD(2)
			EndIf
		initBall()
		Return
	EndIf

	
End Function


;==========================================================================
;============================== Check Collisions ==========================
;==========================================================================
Function checkCollisions()
	w=Abs(bx-lx)
	h=Abs(by-ly)

	;top third of paddle
	If RectsOverlap (bx,by,w,h,px,py,rectw,(recth/3))
		If bspeedy<1 And bspeedy>-1 bspeedy=1
		bspeedy=bspeedy*1.25
		bspeedx=-bspeedx*1.05
		bx=bx+5
		ptimer(0)=MilliSecs()+PFLASH
	;middle third of paddle
	ElseIf RectsOverlap (bx,by,w,h,px,(py+recth/3),rectw,(recth/3))
		bspeedy=-bspeedy*0.75
		bspeedx=-bspeedx*1.1
		bx=bx+5	
		ptimer(0)=MilliSecs()+PFLASH	
	;bottom third of paddle
	ElseIf RectsOverlap (bx,by,w,h,px,(py+recth*2/3),rectw,(recth/3))
		If bspeedy<1 And bspeedy>-1 bspeedy=1
		bspeedy=-bspeedy*1.25
		bspeedx=-bspeedx*1.05
		bx=bx+5		
		ptimer(0)=MilliSecs()+PFLASH	
	;top third of paddle
	ElseIf RectsOverlap (bx,by,w,h,cx,cy,rectw,(recth/3))
		bspeedy=bspeedy*1.25
		bspeedx=-bspeedx*1.05
		bx=bx-5
		ptimer(1)=MilliSecs()+PFLASH		
	;middle third of paddle
	ElseIf RectsOverlap (bx,by,w,h,cx,(cy+recth/3),rectw,(recth/3))
		bspeedy=-bspeedy*0.75
		bspeedx=-bspeedx*1.1
		bx=bx-5	
		ptimer(1)=MilliSecs()+PFLASH	
	;bottom third of paddle
	ElseIf RectsOverlap (bx,by,w,h,cx,(cy+recth*2/3),rectw,(recth/3))
		bspeedy=-bspeedy*1.25
		bspeedx=-bspeedx*1.05
		bx=bx-5	
		ptimer(1)=MilliSecs()+PFLASH	
	EndIf

End Function

;==========================================================================
;=============================== Initialise Ball ==========================
;==========================================================================
Function initBall()

	;initialise ball
	bx=gwidth/2
	lx=bx
	by=gheight/2
	ly=by
	bspeedx=gwidth/(Rnd(1,2)*fps)
	If Rand(0,1) bspeedx=-bspeedx
	bspeedy=gheight/(Rnd(2,3)*fps)
	If Rand(0,1) bspeedy=-bspeedy
	py=(gheight-recth)/2
	cy=(gheight-recth)/2
	
End Function


;==========================================================================
;=============================== Update AI ================================
;==========================================================================
Function updateAI()
	
	If bspeedx<0
		If (cy+recth/2)<(gheight*2/5)
			cy=cy+pspeed
		ElseIf (cy+recth/2)>(gheight*3/5)
			cy=cy-pspeed
		EndIf
	ElseIf bspeedx>0
		;if ball is going up
		If bspeedy<0
			;if ball is higher than bat
			If by<(cy+recth/4)
				cy=cy-pspeed
			;if ball is lower than bat
			ElseIf by>(cy+recth*3/4)
				cy=cy+pspeed
			EndIf
		;if ball is going down	
		Else
			;if ball is lower than bat
			If by>(cy+recth*3/4)
				cy=cy+pspeed
			;if ball is higher
			ElseIf by<(cy+recth/4)
				cy=cy-pspeed
			EndIf
		EndIf
	EndIf

End Function



;==========================================================================
;=============================== Update Paddles ===========================
;==========================================================================
Function updatePaddle()

	If cy<BORDER
		cy=BORDER
	ElseIf (cy+recth)>gheight-BORDER
		cy=gheight-recth-BORDER
	EndIf

	If py<BORDER
		py=BORDER
	ElseIf (py+recth)>gheight-BORDER
		py=gheight-recth-BORDER
	EndIf
	
	;color paddle flash
	For i=0 To 1
		pcolor(i,0)=247
		pcolor(i,1)=235
		pcolor(i,2)=5
		
		If ptimer(i)>MilliSecs()+PFLASH*4/5
			pcolor(i,0)=125
			pcolor(i,1)=119
			pcolor(i,2)=2	
		ElseIf ptimer(i)>MilliSecs()+PFLASH*3/5
			pcolor(i,0)=148
			pcolor(i,1)=140
			pcolor(i,2)=3		
		ElseIf ptimer(i)>MilliSecs()+PFLASH*2/5
			pcolor(i,0)=173
			pcolor(i,1)=165
			pcolor(i,2)=3		
		ElseIf ptimer(i)>MilliSecs()+PFLASH*1/5			
			pcolor(i,0)=200
			pcolor(i,1)=190
			pcolor(i,2)=4	
		ElseIf ptimer(i)>MilliSecs()
			pcolor(i,0)=228
			pcolor(i,1)=218
			pcolor(i,2)=5	
		EndIf

	Next

End Function


;==========================================================================
;=============================== Update HUD ===============================
;==========================================================================
Function updateHUD(p=3)

	If p=10
		pausetime=500+MilliSecs()
	ElseIf p=1
		pausetime=2000+MilliSecs()
	ElseIf p=2
		pausetime=2000+MilliSecs()
	ElseIf p4=4
		pausetime=3000+MilliSecs()
	ElseIf p=5
		pausetime=3000+MilliSecs()
	ElseIf p=7
		pausetime=2000+MilliSecs()
	Else
		pausetime=1500+MilliSecs()
	EndIf
	
	pause=p

End Function


;==========================================================================
;=============================== Draw HUD =================================
;==========================================================================
Function drawHUD(i=1)

	If pause>0 SetFont arialb

	If pause=3
		Color 191,49,13
		Text gwidth/2,gheight/2,"Get Ready!",True,True
	ElseIf pause=1
		Color 255,128,0
		Text gwidth/2,gheight/2,"Player Scores!",True,True
	ElseIf pause=2
		Color 0,128,0	
		Text gwidth/2,gheight/2,"Computer Scores!",True,True
	ElseIf pause=4
		Color 255,128,0	
		Text gwidth/2,gheight/2,"Player Wins!",True,True
	ElseIf pause=5
		Color 0,128,0	
		Text gwidth/2,gheight/2,"Computer Wins!",True,True
	ElseIf pause=6
		Color 191,49,13
		Text gwidth/2,gheight/2,"Play Again? Y/N",True,True
	ElseIf pause=7
		Color 255,255,255
		Text gwidth/2,(gheight-FontHeight())/2,"Thanks for Playing",True,True
		Color 51,51,255
		Text gwidth/2,(gheight+FontHeight())/2,"Paddle Ball",True,True
		Color 191,49,13
		Text gwidth/2,(gheight+2*FontHeight())/2,"Presented by WillK",True
	ElseIf pause=11
		Color 255,255,255
		Text gwidth/2,(gheight-FontHeight())/2,"Game Paused!",True,True
	EndIf
	
	Color 192,192,192
	SetFont arial
	If i=1 Text gwidth/2,0,"PLAYER: "+pscore +"        "+"COMPUTER: "+cscore,True	
	
End Function


;==========================================================================
;============================= Draw Title Screen ==========================
;==========================================================================
Function drawTitle()

	Color 191,49,13
	SetFont arial
	Text gwidth/2,50,"Silly Little Paddle Ball Game",True
	Color 0,128,64
	SetFont arialc
	Text gwidth/2,100,"Up/Down arrows move paddle",True
	Text gwidth/2,100+FontHeight(),"Press P to Pause the Action",True
	
	Color 250,250,250
	Text gwidth/2,300,"Press Space to Begin",True
	Flip
	WaitKey

End Function