Wednesday Workshop

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|658|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-

Flight of the Pixel

by pebu for Workshop #001

Guide the pixel in it's flight.

Cursors

; Flight of the Pixel
; Written by Pebu for the CodersWorkshop '5 Objects' compo
Const SCREEN_WIDTH = 800
Const SCREEN_HEIGHT = 600

Const HALF_WIDTH = SCREEN_WIDTH / 2
Const HALF_HEIGHT = SCREEN_HEIGHT / 2

Const FPS = 30

Const STATE_QUIT = -1
Const STATE_TITLE = 0
Const STATE_PLAYING = 1
Const STATE_GAMEOVER = 2
Const STATE_WON = 3

Const FRICTION# = 0.1
Const GRAVITY# = 0.25
Const ACCELERATION# = 0.5
Const MAX_SPEED# = 10

Const MAX_OBJECTS = 4
Const OBJ_RECT = 1
Const OBJ_OVAL = 2

Const EXPLO_MAXSIZE# = 10
Const EXPLO_GROWTH# = 0.5

Type tPlayerData
	Field x#, y#, dx#, dy#
End Type

Type tObjectData
	Field r, g, b		; Colour
	Field ObType		; Rect or Oval
	Field x, y, w, h	; Dimensions of object
End Type

Type tRoomData
	Field id		; Room id = index into array
	Field r, g, b	; ClsColor for this room
	Field NumObjects
	Field Objects.tObjectData[MAX_OBJECTS-1]
End Type

Global gPlayer.tPlayerData
Global gFPSTimer
Dim gaRooms.tRoomData(0)
Global gNumRooms, gCurrentRoom
Global gStartTime
Global geGameState

; Initialise
Graphics SCREEN_WIDTH, SCREEN_HEIGHT, 0, 1
SetBuffer BackBuffer()
HidePointer
gFPSTimer = CreateTimer(FPS)
InitRooms()
geGameState = STATE_TITLE

; Play
Repeat
	Select geGameState
		Case STATE_TITLE
			TitleScreen()
		Case STATE_PLAYING
			PlayGame()
		Case STATE_GAMEOVER
			GameOver()
		Case STATE_WON
			WinGame()
	End Select
Until geGameState = STATE_QUIT

; Finish up
Delete Each tPlayerData
Delete Each tObjectData
Delete Each tRoomData
FreeTimer gFPSTimer
ShowPointer
End

; TitleScreen() - show the title screen and wait for player to start a game
Function TitleScreen()
	; Set current room to 0, which is important as room 0 only has 
	; 2 objects, leaving 3 free for title screen text
	EnterRoom(0)
	
	; Loop drawing title screen until use presses space to play
	; or esc to quit
	Repeat
	
		If KeyHit(57) Then geGameState = STATE_PLAYING
		If KeyHit(1) Then geGameState = STATE_QUIT

		; Wait for next frame, then draw
		WaitTimer gFPSTimer
		Cls
		DrawRoom(gCurrentRoom)

		; Title screen text - 3 objects
		Color 255, 255, 255
		Text HALF_WIDTH, HALF_HEIGHT -100, "FLIGHT OF THE PIXEL", True, True
		Text HALF_WIDTH, HALF_HEIGHT, "Guide your little dot to the safety of the yellow screen", True, True
		Text HALF_WIDTH, HALF_HEIGHT+20, "Left and Right cursors to move, Up cursor to thrust. Press Space to play", True, True
	
		Flip
	
	Until geGameState <> STATE_TITLE
	
	; Prepare for a new game
	If geGameState = STATE_PLAYING Then 
		InitGame()
	EndIf
	
End Function

; InitGame() - set up for new game
Function InitGame()
	Delete Each tPlayerData
	gPlayer = New tPlayerData
	gPlayer\x = HALF_WIDTH
	gPlayer\y = HALF_HEIGHT
	gPlayer\dx = 0
	gPlayer\dy = 0
	EnterRoom(0)
	MoveMouse HALF_WIDTH, HALF_HEIGHT
	gStartTime = MilliSecs()
End Function

; PlayGame() - play a single frame of the game
Function PlayGame()

	Local pixel

	; Get input and update player
	UpdatePlayer()
	
	; Wait for next frame, then draw
	WaitTimer gFPSTimer
	Cls
	DrawRoom(gCurrentRoom)

	; Grab the colour of the pixel underneath the player now, before we draw him
	pixel = ReadPixel(gPlayer\x, gPlayer\y, BackBuffer())
	
	Color 255, 255,255
	Oval gPlayer\x-2, gPlayer\y-2, 4, 4, True
	Flip

	; Perform collision checks using the colour we grabbed earlier
	If CollisionCheck(gPlayer\x, gPlayer\y, pixel) Then 
		geGameState = STATE_GAMEOVER
	ElseIf (gCurrentRoom = gNumRooms - 1) And (gPlayer\x > 52) Then
		; Made it into the final room
		geGameState = STATE_WON
	EndIf

	If KeyHit(1) Then geGameState = STATE_QUIT

End Function

; GameOver() - do the explosion when the player dies and then
; display game over message and wait till player  presses space
Function GameOver()

	Local exploSize# = 1

	Repeat
		If exploSize < EXPLO_MAXSIZE Then
			exploSize = exploSize + EXPLO_GROWTH
		EndIf
		If KeyHit(57) Then geGameState = STATE_TITLE
		If KeyHit(1) Then geGameState = STATE_QUIT

		; Wait for next frame, then draw
		WaitTimer gFPSTimer
		Cls
		DrawRoom(gCurrentRoom)
		If exploSize < EXPLO_MAXSIZE Then
			Color 255, 0, 0: Oval gPlayer\x-exploSize, gPlayer\y-exploSize, exploSize*2, exploSize*2, True
		Else
			Color 255, 0, 0: Text HALF_WIDTH, HALF_HEIGHT, "GAME OVER - PRESS SPACE TO PLAY AGAIN", True, True
		EndIf
		Flip

	Until geGameState <> STATE_GAMEOVER

End Function

; WinGame() - Display "Well Done" message if player makes it to final screen
Function WinGame()
	
	; Calculate final time
	TimeTaken# = (MilliSecs() - gStartTime) / 1000.0
	
	Repeat
	
		If KeyHit(57) Then geGameState = STATE_TITLE
		If KeyHit(1) Then geGameState = STATE_QUIT

		; Wait for next frame, then draw
		WaitTimer gFPSTimer
		Cls
		DrawRoom(gCurrentRoom)

		; Title screen text - 3 objects
		Color 255, 255, 255
		Text HALF_WIDTH, HALF_HEIGHT - 100, "WELL DONE - YOU MADE IT!!", True, True
		Text HALF_WIDTH, HALF_HEIGHT, "Time taken: " + Str(TimeTaken) + " seconds.", True, True
		Text HALF_WIDTH, HALF_HEIGHT+50, "Press Space to Play or Esc to Quit", True, True
	
		Flip
	
	Until geGameState <> STATE_WON
	
End Function

; CollisionCheck() - detect if pixel at x,y is wall or floor
Function CollisionCheck(x#, y#, pixelColour)

	Local bHit = False
	Local r,g,b

	; Get the red, green and blue components of the colour
	r = pixelColour Shr 16 And 255
	g = pixelColour Shr 8 And 255
	b = pixelColour And 255
	
	; If r,g,b are all zero then OK - floor tile
	; Otherwise it's a wall tile
	If r+g+b = 0 Then
		bHit = False
	Else
		bHit = True
	EndIf
		
	Return bHit

End Function

; UpdatePlayer() - get player input and update their position on screen
Function UpdatePlayer()

	; Get keypresses and update dx/dy accordingly
	If KeyDown(205) Then
		gPlayer\dx = gPlayer\dx + ACCELERATION
	ElseIf KeyDown(203) Then
		gPlayer\dx = gPlayer\dx - ACCELERATION
	EndIf
	
	If KeyDown(200) Then
		gPlayer\dy = gPlayer\dy - ACCELERATION
	Else
		; If player is not pressing Up, apply gravity
		gPlayer\dy = gPlayer\dy + GRAVITY
	EndIf

	; Apply friction to horizontal movement
	If gPlayer\dx > 0 Then
		gPlayer\dx = gPlayer\dx - FRICTION
		If gPlayer\dx < 0 Then gPlayer\dx = 0
	ElseIf gPlayer\dx < 0 Then
		gPlayer\dx = gPlayer\dx + FRICTION
		If gPlayer\dx > 0 Then gPlayer\dx = 0
	EndIf

	; Prevent speed from going too high
	If gPlayer\dx > MAX_SPEED Then 
		gPlayer\dx = MAX_SPEED
	ElseIf gPlayer\dx < -MAX_SPEED Then 
		gPlayer\dx = -MAX_SPEED
	EndIf
	If gPlayer\dy > MAX_SPEED Then 
		gPlayer\dy = MAX_SPEED
	ElseIf gPlayer\dy < -MAX_SPEED Then 
		gPlayer\dy = -MAX_SPEED
	EndIf

	; Update player coordinates
	gPlayer\x = gPlayer\x + gPlayer\dx
	gPlayer\y = gPlayer\y + gPlayer\dy
	
	; Check for wrap around screen on left and right
	; and update the current room
	If gPlayer\x < 0 Then 
		If gCurrentRoom > 0 Then
			gPlayer\x = SCREEN_WIDTH
			EnterRoom(gCurrentRoom - 1)
		EndIf
	ElseIf gPlayer\x > SCREEN_WIDTH Then 
		If gCurrentRoom < gNumRooms - 1 Then
			gPlayer\x = 0
			EnterRoom(gCurrentRoom + 1)
		EndIf
	EndIf
	
End Function

; EnterRoom() - set globals and cls colour upon entering a room
Function EnterRoom(iRoom)
	gCurrentRoom = iRoom
	ClsColor gaRooms(iRoom)\r, gaRooms(iRoom)\g, gaRooms(iRoom)\b
End Function

; DrawRoom() - draws the specified room objects
; Note - assumes CLS has already been called.
Function DrawRoom(iRoom)
	Local iCtr
	Local ob.tObjectData
	For iCtr = 0 To gaRooms(iRoom)\NumObjects - 1
		ob = gaRooms(iRoom)\Objects[iCtr]
		Color ob\r, ob\g, ob\b
		Select ob\ObType
			Case OBJ_RECT
				Rect ob\x, ob\y, ob\w, ob\h, True
			Case OBJ_OVAL
				Oval ob\x, ob\y, ob\w, ob\h, True
		End Select
	Next
End Function

; InitRooms() - Initialise rooms array
Function InitRooms()

	Local nRooms, iRoom, nObjects, iObject
	Local rm.tRoomData
	Local ob.tObjectData
	Local bWall

	Delete Each tObjectData
	Delete Each tRoomData

	Restore ROOM_DATA
	Read gNumRooms
	Dim gaRooms.tRoomData(gNumRooms - 1)
	For iRoom = 0 To gNumRooms - 1
		rm = New tRoomData
		
		rm = New tRoomData
		rm\id = iRoom
		Read rm\r, rm\g, rm\b

		Read rm\NumObjects
		For iObject = 0 To rm\NumObjects - 1
			ob = New tObjectData
			Read ob\ObType, bWall
			Read ob\x, ob\y, ob\w, ob\h
			If bWall Then
				ob\r = rm\r: ob\g = rm\g: ob\b = rm\b
			Else
				ob\r = 0: ob\g = 0: ob\b = 0
			EndIf
			rm\Objects[iObject] = ob
		Next
		
		gaRooms(iRoom) = rm
	Next
End Function

.ROOM_DATA
Data 7
; ROOM 0 - start room
Data 0, 200, 0
Data 2
Data OBJ_RECT, 0, 50, 50, SCREEN_WIDTH-100, SCREEN_HEIGHT-100
Data OBJ_RECT, 0, SCREEN_WIDTH-100, HALF_HEIGHT-50, 100, 100
; ROOM 1 
Data 128, 0, 128
Data 3
Data OBJ_RECT, 0, 0, HALF_HEIGHT-50, SCREEN_WIDTH, 100
Data OBJ_RECT, 0, 100, 100, SCREEN_WIDTH-200, SCREEN_HEIGHT-200
Data OBJ_OVAL, 1, HALF_WIDTH-100, HALF_HEIGHT-100, 200, 200
; ROOM 2
Data 0, 50, 200
Data 3
Data OBJ_RECT, 0, 0, HALF_HEIGHT-50, HALF_WIDTH, 100
Data OBJ_RECT, 0, HALF_WIDTH-50, 50, HALF_WIDTH+50, SCREEN_HEIGHT-100
Data OBJ_RECT, 1, HALF_WIDTH + 50, 100, HALF_WIDTH, SCREEN_HEIGHT-200
; ROOM 3
Data 20, 100, 20
Data 3
Data OBJ_OVAL, 0, -500, 50, 1000, SCREEN_HEIGHT-100
Data OBJ_RECT, 0, HALF_WIDTH, HALF_HEIGHT-25, HALF_WIDTH, 50
Data OBJ_OVAL, 1, -450, 100, 900, SCREEN_HEIGHT-200
; ROOM 4
Data 50, 200, 200
Data 3
Data OBJ_RECT, 0, 0, HALF_HEIGHT-25, SCREEN_WIDTH, 50
Data OBJ_RECT, 0, HALF_WIDTH/2, 50, HALF_WIDTH, HALF_HEIGHT-75
Data OBJ_RECT, 1, (HALF_WIDTH/2)+50, 100, HALF_WIDTH-100, HALF_HEIGHT-75
; ROOM 5
Data 200, 150, 150
Data 3
Data OBJ_RECT, 0, 0, HALF_HEIGHT-25, SCREEN_WIDTH, 50
Data OBJ_OVAL, 0, HALF_WIDTH-(HALF_HEIGHT-50), 50, SCREEN_HEIGHT-100, SCREEN_HEIGHT-100
Data OBJ_OVAL, 1, HALF_WIDTH-(HALF_HEIGHT-100), 100, SCREEN_HEIGHT-200, SCREEN_HEIGHT-200
; Last room
Data 200, 200, 0
Data 2
Data OBJ_RECT, 0, 50, 50, SCREEN_WIDTH-100, SCREEN_HEIGHT-100
Data OBJ_RECT, 0, 0, HALF_HEIGHT-25, 100, 50
; End of room data

Multiball Pong

by Pebu for Workshop #029

Keep the balls bouncing

Mouse

; MULTI-BALL PONG
; Created by Pebu for the Coders Workshop Pong Compo

; CONSTANTS
Const TARGET_FPS = 60

Const SCREEN_WIDTH = 640
Const SCREEN_HEIGHT = 480

Const SCREEN_HALFWIDTH = SCREEN_WIDTH / 2
Const SCREEN_HALFHEIGHT = SCREEN_HEIGHT / 2

Const TOP_WALL_Y = 20
Const BOT_WALL_Y = SCREEN_HEIGHT - TOP_WALL_Y
Const END_WALL_X = SCREEN_WIDTH - TOP_WALL_Y

Const PLAYER_1_X = 50
Const PLAYER_WIDTH = 20
Const PLAYER_HEIGHT = 80

Const BALL_MINSPEED = 2
Const BALL_MAXSPEED = 15
Const BALL_SIZE = 20
Const BALL_ACCEL# = 0.25  

; TYPE DEFINITIONS
Type tBall
	Field x#, y#
	Field dx#, dy#
	Field speed#
	Field angle#
End Type

Type tPlayer
	Field x#, y#
	Field dy#
	Field score
End Type

; GLOBALS
Global gPlayer.tPlayer
Global gbGameOver 
Global gBounces, gNumBalls
Global gGameTimer, gbQuit

; INITIALISE
Graphics SCREEN_WIDTH, SCREEN_HEIGHT, 0, 2
SetBuffer BackBuffer()
HidePointer()
gGameTimer = CreateTimer(TARGET_FPS)

; MAIN GAME LOOP
Repeat

	; Set up new game
	gNumBalls = 0: gBounces = 1
	gPlayer = CreatePlayer()
	ball.tBall = CreateBall(BALL_MINSPEED)
	gbGameOver = False
	gbQUit = False
	
	; Play the game until player quits or loses
	Repeat
	
		UpdatePlayer(gPlayer)
		For b.tBall = Each tBall
			UpdateBall(b)
		Next
		If KeyHit(1) Then gbQuit = True
		
		Cls
		DrawBackground()
		DrawPlayer(gPlayer)
		For b.tBall = Each tBall
			DrawBall(b)
		Next
		WaitTimer gGameTimer
		Flip False
		
	Until gbQuit Or gbGameOver
	
	; Game Over routine
	If gbGameOver Then
	
		Repeat
	
			k = GetKey()
			If KeyHit(1) Then gbQuit = True
			
			Cls
			DrawBackground()
			DrawPlayer(gPlayer)
			For b.tBall = Each tBall
				DrawBall(b)
			Next
			Color 255, 0, 0
			Text SCREEN_HALFWIDTH, SCREEN_HALFHEIGHT - 25, "GAME OVER", True, True
			Color 200, 200, 255
			Text SCREEN_HALFWIDTH, SCREEN_HALFHEIGHT + 25, "You scored: " + Str(gPlayer\Score), True, True
			Text SCREEN_HALFWIDTH, SCREEN_HEIGHT - 50, "Press Esc to quit or any other key to play again.", True, True

			WaitTimer gGameTimer
			Flip False
		
		Until gbQuit Or k <> 0
		
	EndIf

	; Clear up 
	Delete Each tPlayer
	Delete Each tBall

Until gbQuit	
ShowPointer()
FreeTimer gGameTimer
End

; PLAYER FUNCTIONS
Function CreatePlayer.tPlayer()

	Local p.tPlayer = New tPlayer
	p\x = PLAYER_1_X
	p\y = SCREEN_HALFHEIGHT
	p\score = 0
		
	Return p	
	
End Function

Function UpdatePlayer(p.tPlayer)

	; Get mouse movement this frame
	p\dy = MouseYSpeed()
	MoveMouse SCREEN_HALFWIDTH, SCREEN_HALFHEIGHT
	
	; Update player position, prevent player from overlapping walls.
	p\y = p\y + p\dy
	If p\y < TOP_WALL_Y Then 
		p\y = TOP_WALL_Y
	ElseIf p\y > BOT_WALL_Y - PLAYER_HEIGHT Then
		p\y = BOT_WALL_Y - PLAYER_HEIGHT 
	EndIf

End Function

Function DrawPlayer(p.tPlayer)

	Color 255, 255, 255
	Rect p\x, p\y, PLAYER_WIDTH, PLAYER_HEIGHT, True

End Function

; BALL FUNCTIONS
Function CreateBall.tBall(speed = BALL_MINSPEED)

	SeedRnd MilliSecs()
	Local b.tBall = New tBall
	
	; Randomise ball's position and direction
	b\y = Rand(TOP_WALL_Y, BOT_WALL_Y - BALL_SIZE)
	b\x = Rand(SCREEN_HALFWIDTH, END_WALL_X - BALL_SIZE)
	
	If speed < BALL_MINSPEED Then speed = BALL_MINSPEED
	If speed > BALL_MAXSPEED Then speed = BALL_MAXSPEED
	b\speed = speed
	
	If b\y < SCREEN_HALFHEIGHT Then
		b\angle = Rand(190,260)
	Else
		b\angle = Rand(100,170)
	EndIf
	ComputeBallDXDY(b)
	
	; Keep track of total number of balls
	gNumBalls = gNumBalls + 1
	
	Return b

End Function

Function ComputeBallDXDY(b.tBall)

	; Calculate DX and DY based on angle and speed
	b\dx = Cos(b\angle) * b\speed
	b\dy = -Sin(b\angle) * b\speed

End Function

Function UpdateBall(b.tBall)

	; Move ball
	b\x = b\x + b\dx
	b\y = b\y + b\dy
	
	; Bounce off walls.
	; No need to calculate angle, just reverse dy or dx depending on the wall that was hit
	If b\y < TOP_WALL_Y Then
	
		b\dy = -b\dy
		b\y = TOP_WALL_Y
	
	ElseIf b\y > BOT_WALL_Y - BALL_SIZE Then
		
		b\dy = -b\dy
		b\y = BOT_WALL_Y - BALL_SIZE
		
	EndIf
	
	If b\x > END_WALL_X - BALL_SIZE Then
	
		b\dx = -b\dx
		b\x = END_WALL_X - BALL_SIZE
	
	EndIf
	
	; Check for going out of bounds
	If b\x < 0 Then
		gbGameOver = True
	ElseIf b\x <= PLAYER_1_X + PLAYER_WIDTH Then
	
		; Check for bat/ball collision
		If RectsOverlap(gPlayer\x, gPlayer\y, PLAYER_WIDTH, PLAYER_HEIGHT, b\x, b\y, BALL_SIZE, BALL_SIZE) Then
		
			; Update the player's score
			gPlayer\score = gPlayer\score + 1
		
			; Reverse the ball's direction and increase its speed
			; b\angle won't reflect the ball's current angle because it is not updated when hitting
			; walls, so we have to recalculate it.
			b\x = gPlayer\x + PLAYER_WIDTH
			ang# = ATan2(b\dy, b\dx)
			b\angle = ang# + 180

			; Alter angle of the ball based on speed of the bat when the ball hit.
			b\angle = b\angle - (gPlayer\dy * 2)

			b\speed = b\speed + BALL_ACCEL
			ComputeBallDXDY(b)
		
			; Check if it's time to add another ball
			gBounces = gBounces - 1
			If gBounces <= 0 Then
				CreateBall(gNumBalls + 1)
				gBounces = gNumBalls
			EndIf
		
		
		EndIf
	
	EndIf

End Function

Function DrawBall(b.tBall)

	Color 255, 255, 0
	Oval b\x, b\y, BALL_SIZE, BALL_SIZE, True

End Function

; BACKGROUND DRAWING FUNCTIONS
Function DrawBackground()

	Color 0, 255, 0
	Rect 0, 0, SCREEN_WIDTH, TOP_WALL_Y, True
	Rect 0, BOT_WALL_Y, SCREEN_WIDTH, TOP_WALL_Y, True
	Rect END_WALL_X, 0, TOP_WALL_Y, SCREEN_HEIGHT, True
	
	Color 0, 0, 0
	Text 100, 5, "Score: " + Str(gPlayer\score)
	Text SCREEN_HALFWIDTH + 100, 5, "Balls: " + Str(gNumBalls)
	
End Function