Wednesday Workshop

-=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- (c) WidthPadding Industries 1987 0|606|0 -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=- -=+=-

Flood Warning

by blanko1324 for Workshop #018

Stop the building from flooding by catching the water in your trusty bucket.

Mouse

Graphics 800,600
SeedRnd MilliSecs()
AppTitle "Flood Warning"

;Wed. Workshop #18: The water challenge.

Type drop
 Field x#,y#
 Field dirx#,diry#
 Field hit#
End Type 

Global bucket_x
Global bucket_y

background = CreateImage(800,600)
 SetBuffer ImageBuffer(background)
  Draw_BG()

SetBuffer BackBuffer()

Global leak_x,leak_y
Global score = 0
Global combo_amt = 0

Global water_level# = 0

Global font1 = LoadFont("Ariel",50,1,0,0)
Global font2 = LoadFont("Ariel",14,0,0,0)

;Opening Loop

Repeat 
Cls 

Draw_Opening()
Update_Spray()

For d.drop = Each drop
 If d\y >= 490
  d\hit = 1
 EndIf 
Next 

Flip
Until MouseHit(1)

FlushKeys()

For d.drop = Each drop
 d\hit = 1
Next 

;Opening End

Global leak_timer = MilliSecs() ;determines when to change holes
Update_Holes(Rand(1,5))

;Main Loop

Repeat 
Cls

If MilliSecs() >= leak_timer + Rand(2000,4000)
 Update_Holes(Rand(1,5))
 leak_timer = MilliSecs()
EndIf 

DrawImage background,0,0
Color 155,155,155
Update_Bucket()

Spray(leak_x,leak_y)
Update_Spray()
Update_Water_Level()

If water_level >= 200
  Exit 
EndIf 

Color 255,255,255
SetFont font2
Text 400,500,"Score: " + score,1,1


Flip
Until KeyHit(1)

;Main End

;End Loop

Repeat
Cls

Color 255,255,255
SetFont font1
Text 400,200,"GAME OVER",1,1
SetFont font2
Text 400,250,"Score: " + score,1,1
Text 400,270,"Press ESC to exit",1,1

If KeyHit(1)
 End
EndIf 

Flip
Until KeyHit(False)

;End End

Function Draw_BG()

 Color 255,255,255
 Rect 300,150,200,200,0 ;Back Wall
 
 Line 0,0,300,150
 Line 0,600,300,350
 Line 800,600,500,350
 Line 800,0,500,150

 Rect 355,230,90,120,0 ;Door
 Oval 365,290,5,5,0 ;Door Knob

End Function 

Function Update_Bucket()

 bucket_x = MouseX()
 bucket_y = MouseY()

 Color 255,255,255
  Line bucket_x - 20,bucket_y - 20,bucket_x + 20,bucket_y - 20
  Line bucket_x - 15,bucket_y + 30,bucket_x + 15,bucket_y + 30
  Line bucket_x - 20,bucket_y - 20,bucket_x - 15,bucket_y + 30
  Line bucket_x + 20,bucket_y - 20,bucket_x + 15,bucket_y + 30
 
 For d.drop = Each drop
  If d\x >= bucket_x - 20 And d\x <= bucket_x + 20 And d\y >= bucket_y - 20 And d\y <= bucket_y - 10
   d\hit = 1 
   score = score + 1
  EndIf 
 Next 

 
End Function 

Function Update_Holes(hole_num)

 Select hole_num
  Case 1
   leak_x = 266
   leak_y = 50
  Case 2
   leak_x = 266*2
   leak_y = 50
  Case 3
   leak_x = 399
   leak_y = 50
  Case 4
   leak_x = 100
   leak_y = 200
  Case 5
   leak_x = 700
   leak_y = 200
 End Select 

End Function

Function Spray(x,y)

 d.drop = New drop
  d\x = x
  d\y = y
  
  If (d\y = 50) 
   d\dirx = Rnd#(-.2,.2)
  EndIf 
  
  If (d\x = 100)
   d\dirx = Rnd#(3,3.2)
  EndIf 

  If (d\x = 700)
   d\dirx = Rnd#(-3,-3.2)
  EndIf 

  d\diry = Rnd#(2,5)
  d\hit = 0

End Function

Function Update_Spray()

 For d.drop = Each drop
  If d\hit = 1
   Delete d
  Else 
   d\x = d\x + d\dirx
   d\y = d\y + d\diry

   d\diry = d\diry + .1

   Color 100,100,255
   Oval d\x - 2,d\y - 2,4,4,1
 
  EndIf 
 Next

Oval leak_x - 2,leak_y - 2,4,4,1

End Function 

Function Update_Water_Level()

 For d.drop = Each drop
  If d\y >= 600 - water_level
   water_level = water_level + .2
   d\hit = 1
  EndIf 
 Next 

Color 100,100,255
Rect 0,600-water_level,800,600-water_level

End Function 

Function Draw_Opening()

 Color 255,255,255
  Rect 400-200,300-200,400,400,0
 
  Rect 400-50,350,100,100,0

  Line 350,350,400,300 ;roof
  Line 450,350,400,300 ;roof

  Line 350,430,200,430 ;ground
  Line 450,430,599,430 ;ground
 
  Rect 375,380,50,70,0 ;door
  
  Oval 380,410,5,5,0 ;doorknob

 Spray(Rnd#(200,600),100)

 SetFont font1 
  Text 400,140,"Flood",1,1
  Text 400,180,"Warning",1,1

 SetFont font2
  Text 400,520,"To Play: Stop the building from flooding by catching the water in your trusty bucket. Dont let the water level get to high",1,1
  Text 400,540,"Press LMB to start and be ready to catch as soon as you press it.",1,1
  Text 400,560,"By: Nick (blanko) Sheets",1,1

End Function